ここでは、アイソヘドラルタイリングIH7（P3）について、解説します。
IH7（P3）
アイソヘドラルタイリングIH7（P3）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP3群の基本図形の各辺の長さを調整したものになっています。
IH7（P3）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
今回、辺\(a\)と辺\(b\)、辺\(c\)と辺\(d\)、および辺\(e\)と辺\(f\)は、それぞれ同じ長さを持つように設定します。また、辺\(a\)と辺\(b\)の交点、辺\(c\)と辺\(d\)の交点、および辺\(e\)と辺\(f\)の交点はそれぞれ三角格子の近接する3つの頂点（黒点）と一致するようにとります。さらに、辺\(a\)と辺\(b\)の間の角、辺\(c\)と辺\(d\)の間の角、および辺\(e\)と辺\(f\)の間の角をそれぞれ120°にとります。あとは、辺\(f\)の長さを\(r_1\)とし、辺\(a\)と辺\(b\)の交点と辺\(e\)と辺\(f\)の交点を結んだ線分と辺\(f\)との間の角度\(\alpha\)を設定すると、この基本図形の形を決めることができます。
IH7（P3）の基本図形を並べる
このIH7（P3）の基本図形をP3群の対称性を保ちながら並べると、以下のような図形が得られます。
IH7（P3）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a\)と辺\(b\)、辺\(c\)と辺\(d\)、および辺\(e\)と辺\(f\)がそれぞれ異なる向きに重なっています。つまり、辺\(a\)を変形し、辺\(b\)は、変形した辺\(a\)を上下左右反転した形状に変形します。辺\(c\)と辺\(d\)、および辺\(e\)と辺\(f\)についても同様な変形を行うことができます。それにより、隣り合う基本図形同士を重ねることなくP3群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.95にあるIH7（P3）の例を参考に、このルールに従ってIH7（P3）の基本図形を下図のように変形してみました。
この変形した基本図形をP3群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000,1000,P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと列の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP3(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH7_P3_transformation.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = PVector.fromAngle(0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
}
}
}
// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
float r1, alpha;
r1 = 11.0/15.0 * 1.0/sqrt(3.0) * scalar;
alpha = 20.0;
v[5] = new PVector(0.0,0.0);
v[1] = new PVector(1.0/sqrt(3.0) * scalar, 0.0);
v[1].rotate(radians(90.0));
v[3] = new PVector(1.0/sqrt(3.0) * scalar, 0.0);
v[3].rotate(radians(30.0));
v[0] = new PVector(r1, 0.0);
v[0].rotate(radians(90.0+alpha));
v[2] = v[0].copy();
v[2].sub(v[1].copy());
v[2].rotate(radians(120.0));
v[2].add(v[1].copy());
v[4] = v[2].copy();
v[4].sub(v[3].copy());
v[4].rotate(radians(120.0));
v[4].add(v[3].copy());
// 六角形を変形する
PShape hexagon = createShape();
hexagon.beginShape();
PVector[] auxiliary_point = new PVector[5];
// 辺aを変形する
hexagon.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, -2.0/3.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[1].x, v[1].y);
// 辺bを辺aと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 5.0/8.0, 2.0/3.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[2].x, v[2].y);
// 辺cを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, -1.0/2.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[3].x, v[3].y);
// 辺dを辺cと同じ形を上下左右反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, 1.0/2.0);
hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[4].x, v[4].y);
// 辺eを変形する
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 1.0/4.0, -1.0/2.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[5], 3.0/5.0, 1.0/4.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[5].x, v[5].y);
// 辺fを辺dと同じ形を上下反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[5], v[0], 2.0/5.0, -1.0/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[5], v[0], 3.0/4.0, 1.0/2.0);
hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[0].x, v[0].y);
hexagon.endShape();
return hexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP3(){
tile = createShape(GROUP); // PShapeのグループを作る
for (int i=0; i<3; i++){
PShape hexagon = transformHexagon(); // 変形した六角形の生成
hexagon.rotate(2 * PI * i / 3); // 120度回転
tile.addChild(hexagon); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
tile.resetMatrix();
tile.translate(vec.x, vec.y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
// 格子点を描く
for (PVector[] vecArr: lattice){
for (PVector vec : vecArr){
circle(vec.x, vec.y,10);
}
}
}