IH40（P6M）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH40（P6M）

ここでは、アイソヘドラルタイリングIH40（P6M）について、解説します。

IH40（P6M）

アイソヘドラルタイリングIH40（P6M）の基本図形は以下のような形になります。

IH40（P6M）の基本図形

これは、記事「基本図形の形を考える」で示したP6M群の基本図形を2つ組み合わせたものになっています。

IH40（P6M）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH40（P6M）の基本図形のサイズ

今回、三角形は頂角が120°となる二等辺三角形に設定します。そして、辺\(a\)の2つの端点と辺\(a\)の中点は三角格子点（黒点）と一致するようにとり、辺\(b\)と辺\(b’\)の交点は近接する三角格子点の重心（赤点）と一致するようにとります。

IH40（P6M）の基本図形を並べる

このIH40（P6M）の基本図形をP6M群の対称性を保ちながら並べると、以下のような図形が得られます。

IH40（P6M）による図形

IH40（P6M）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH40（P6M）の基本図形に対する辺のラベルと向き

辺\(b\)と辺\(b′\)は同じ辺となります。

辺\(a\)については今回変形できません。これは下で説明します。また、辺\(b\)は両側のラベルが同じで同じ向きに重なっていますので、辺\(b\)も変形できません。つまり、IH40（P6M）の基本図形は変形することができないことになります。

※辺aの変形について

『辺\(a\)が変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH40（P6M）の基本図形を記事「基本図形の形を考える」で示したP6M群の基本図形に分けて考えてみます。

P6M群の基本図形に分ける

このとき、辺\(a\)は２つの辺\(a’\)に分けられます。辺\(a\)は辺\(a’\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（ここでは点線）に対して線対称になることになります。一方、辺\(a’\)の両側のラベルは同じで同じ向きに重なっています。これは辺\(a’\)が変形できないことを示しています。つまり、辺\(a\)は変形できないことが分かります。

IH40（P6M）の基本図形に模様をつける

IH40（P6M）の基本図形は変形できませんので、代わりに模様をつけてみます。

IH40（P6M）の基本図形は以下の図のように赤点線でしめした軸に対して線対称な図形になります。

IH40（P6M）の基本図形の対称性

ここでは、この対称性を考慮して、書籍「装飾パターンの法則」のp.100にあるIH40（P6M）の例を参考に、以下のように模様を描いてみました。

IH40（P6M）の基本図形に模様を描く

この模様を描いた基本図形をP6M群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。

模様を描いたIH40（P6M）の基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 6; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6M(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("IH40_P6M_decoration.jpg");
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 2][row_num];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+2)*scalar)-scalar, v.y); 
    }
  }
}

// 三角形に模様を描く関数（基本図形）
PShape decorateTriangle(){
  
  PVector[] v = new PVector[3]; // 三角形の頂点

  v[0] = new PVector(0.0, 0.0);
  v[1] = base[0].copy().mult(2.0 * scalar);
  v[2] = new PVector(0.0, -base[1].y * scalar * 2.0 / 3.0);
  v[2].add(base[0].copy().mult(scalar));

  // 三角形を描く
//  fill(255,255,255);
  noFill();
  PShape tri = createShape();
  tri.beginShape(TRIANGLES); // 3点ずつの頂点から直角三角形を作る
  for (int i=0; i<3; i++){
    tri.vertex(v[i].x, v[i].y);
  }  
  tri.endShape();
  
  // 模様を描く
  fill(200,0,0,128);
  PVector center = new PVector((v[0].x+v[1].x)/2.0, (v[0].y+v[1].y)/2.0);
  PShape pattern = createShape();
  pattern.beginShape();
  PVector[] auxiliary_point = new PVector[6]; 
  auxiliary_point[0] = getAuxiliaryPoint(v[2], center, 1.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], center, 4.0/5.0, 1.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], center, 1.0, 1.0/2.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], center, 4.0/5.0, 0.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], center, 1.0, -1.0/2.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[2], center, 4.0/5.0, -1.0);
  pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  pattern.bezierVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y); 
  pattern.bezierVertex(auxiliary_point[4].x, auxiliary_point[4].y, auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[0].x, auxiliary_point[0].y); 
  pattern.endShape();
  
  PShape decoratedTri = createShape(GROUP);
  decoratedTri.addChild(tri);
  decoratedTri.addChild(pattern);

  return decoratedTri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP6M(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<3; i++){
    for (int j=0; j<2; j++){
      PShape tri = decorateTriangle(); // 三角形の生成
      tri.scale(1, pow(-1, j)); // x軸を中心に鏡映
      tri.rotate(PI * i / 3.0); // 60度回転
      tile.addChild(tri); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }

  // 格子点を描く
  noFill();
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}

コメントを残す