IH2（PG）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH2（PG）

ここでは、アイソヘドラルタイリングIH2（PG）について、解説します。

IH2（PG）

アイソヘドラルタイリングIH2（PG）の基本図形は以下のような形になります。

IH2（PG）の基本図形

これは、記事「基本図形の形を考える」で示した長方格子の縦横比を大きくした場合のPG群の基本図形を少し傾けたものになっています。

IH2（PG）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH2（PG）の基本図形のサイズ

このとき、辺\(d\)、辺\(e\)のそれぞれの中点（黒点）は長方格子の横方向の近接点となるようにします。また、辺\(a\)、辺\(b\)のそれぞれの中点（赤点）はその間の距離が長方格子の横隣り同士の点の長さと一致するようにし、長方格子の横方向のずれは\(r_4\)となるようにします。縦方向をみると、上図の\(r_1, r_2, r_3\)は\(r_1+r_2+r_3\)が長方格子の縦方向の近接点同士距離の半分になるように調整します。

IH2（PG）の基本図形を並べる

このIH2（PG）の基本図形をPG群の対称性を保ちながら並べると、以下のような図形が得られます。

IH2（PG）による図形

丸印は長方格子の点を表しています。上図では長方格子点が基本図形の辺の中点上に乗っていますが、一般的には辺上に乗っている必要はないです。ただ、辺の中点と長方格子の位置を一致させておくと、プログラミングする際に基本図形の位置を確定させることができるので、基本図形を並べていく際に便利です。

IH2（PG）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH2（PG）の基本図形に対する辺のラベルと向き

辺\(a\)と辺\(b\)、辺\(d\)と辺\(e\)がそれぞれ同じ向きに重なっています。つまり、辺\(a\)を変形し、辺\(b\)は、変形した辺\(a\)を上下反転した形状に変形します。また辺\(d\)と辺\(e\)についても同じように変形します。一方、辺\(c\)と辺\(f\)が異なる向きに重なっています。つまり、辺\(c\)を変形し、辺\(f\)は、変形した辺\(c\)を上下左右反転した形状に変形します。それにより、隣り合う基本図形同士を重ねることなくPG群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.94にあるIH2（PG）の例を参考に、このルールに従ってIH2（PG）の基本図形を下図のように変形してみました。

IH2（PG）の基本図形の変形

この変形した基本図形をPG群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は長方格子点も示しています。

IH2（PG）の変形した基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePG(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH2_PG_transformation.jpg");
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 2.0);
  base[1].mult(3.6);
}

// 長方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
    }
  }
}

// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
  
  float r1, r2, r3, r4;
  r1 = 0.1;
  r3 = 0.15;
  r2 = 1.0 - r1 - r3;
  r4 = 0.4;
  PVector[] v_ax = new PVector[3]; // 補助ベクトル
  v_ax[0] = new PVector( base[0].x * scalar / 2.0, base[1].y * scalar / 2.0 * r1 ); 
  v_ax[1] = new PVector( base[0].x * scalar / 2.0 * r4, -base[1].y * scalar / 2.0 * r2 );
  v_ax[2] = new PVector( -base[0].x * scalar / 2.0, -base[1].y * scalar / 2.0 * r3 );

  PVector[] v = new PVector[6]; // 六角形の頂点
  v[0] = new PVector(0.0,0.0);
  v[0].sub(v_ax[0]);
  v[1] = new PVector(0.0,0.0);
  v[1].add(v_ax[0]);
  v[2] = v[0].copy();
  v[2].add(base[0].copy().mult(2.0 * scalar));
  v[3] = v[2].copy();
  v[3].add(v_ax[1]);
  v[4] = v[3].copy();
  v[4].add(v_ax[2].copy().mult(2.0));
  v[5] = v[0].copy();
  v[5].add(v_ax[1]);
  
  // 六角形を変形する
  PShape hexagon = createShape();
  hexagon.beginShape(); 
  PVector[] auxiliary_point = new PVector[2];
  // 辺aを変形する
  hexagon.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/3.0, -1.0/2.0); 
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[1].x, v[1].y);
  // 辺bをを辺aと同じ形を上下反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/3.0, 1.0/2.0); 
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[2].x, v[2].y);
  // 辺cを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, -1.0/4.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, 1.0/2.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[3].x, v[3].y);
  // 辺dを変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, -1.0/2.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[4].x, v[4].y);
  // 辺eを辺dと同じ形を上下反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 1.0/4.0, 1.0/2.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, v[5].x, v[5].y);
  // 辺fを辺cと同じ形を上下左右反転した形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[5], v[0], 1.0/4.0, -1.0/2.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[5], v[0], 3.0/4.0, 1.0/4.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[0].x, v[0].y);

  hexagon.endShape();
  
  return hexagon;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTilePG(){
  PShape rectangle;
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    rectangle = transformHexagon(); // 六角形の生成
    rectangle.scale(1,pow(-1, i)); // 六角形を反転
    rectangle.translate(i*scalar, 0.0); // 六角形の位置を調整
    tile.addChild(rectangle); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}

コメントを残す