ここでは、アイソヘドラルタイリングIH20（P6M）について、解説します。
Contents
IH20（P6M）
アイソヘドラルタイリングIH20（P6M）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP6M群の基本図形を12個組み合わせたものになっています。
IH20（P6M）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
IH20（P6M）の基本図形は正六角形で、上図のように点線で12個の直角三角形に分けると、各直角三角形は記事「基本図形の形を考える」で示したP6M群の基本図形になっています。
今回、各辺の中点と六角形の重心は、近接する三角格子点（黒点）の並びとなるように設定します。
IH20（P6M）の基本図形を並べる
このIH20（P6M）の基本図形をP6M群の対称性を保ちながら並べると、以下のような図形が得られます。
IH20（P6M）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
今回、正六角形の各辺は同じ辺となります。
辺\(a\)は両側のラベルが同じになっていますが、今回辺\(a\)は変形できません。
※辺\(a\)の変形について
『辺\(a\)は変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH20（P6M）の基本図形を記事「基本図形の形を考える」で示したP6M群の基本図形に分けて考えてみます。
このとき、辺\(a\)は２つの辺\(a’\)に分けられます。辺\(a\)は辺\(a’\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線に対して線対称になることになります。一方、辺\(a’\)は両辺のラベルが同じで向きも同じになっていますので、辺\(a’\)は変形できないことになります。つまり、辺\(a\)は変形できないことになります。
IH20（P6M）の基本図形に模様をつける
IH20（P6M）の基本図形は変形できませんので、代わりに模様をつけてみます。
IH20（P6M）の基本図形は以下の図のように赤点線で示した軸に対して線対称であり、また正六角形の重心（赤六角星形点）を中心とした60°回転について対称な図形になります。
ここでは、この対称性を考慮して、書籍「装飾パターンの法則」のp.97にあるIH20（P6M）の例を参考に、以下のように模様を描いてみました。
この模様を描いた基本図形をP6M群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP6M(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH20_P6M_decoration.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x - ((j/2) + 2) * scalar, v.y);
}
}
}
// 六角形に模様を描く関数（基本図形）
PShape decorateHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
for(int i=0; i<6; i++){
v[i] = PVector.fromAngle(radians(150)-i*radians(60));
v[i].mult(2.0 / sqrt(3.0) * scalar);
}
// 六角形を描く
PShape hexagon = createShape();
hexagon.beginShape();
for(int i=0; i<6; i++){
hexagon.vertex(v[i].x, v[i].y);
}
hexagon.endShape(CLOSE);
// 模様を描く
fill(200,0,0,128);
PVector center = new PVector(0.0,0.0);
PShape pattern = createShape();
pattern.beginShape();
PVector[] auxiliary_point = new PVector[24];
auxiliary_point[0] = getAuxiliaryPoint(v[0], center, 1.0/2.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], center, 0.0, 1.0/2.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0].copy().add(v[1].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], center, 0.0, -1.0/2.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], center, 1.0/2.0, 0.0);
auxiliary_point[5] = getAuxiliaryPoint(v[1], center, 0.0, 1.0/2.0);
auxiliary_point[6] = getAuxiliaryPoint(v[1].copy().add(v[2].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[7] = getAuxiliaryPoint(v[2], center, 0.0, -1.0/2.0);
auxiliary_point[8] = getAuxiliaryPoint(v[2], center, 1.0/2.0, 0.0);
auxiliary_point[9] = getAuxiliaryPoint(v[2], center, 0.0, 1.0/2.0);
auxiliary_point[10] = getAuxiliaryPoint(v[2].copy().add(v[3].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[11] = getAuxiliaryPoint(v[3], center, 0.0, -1.0/2.0);
auxiliary_point[12] = getAuxiliaryPoint(v[3], center, 1.0/2.0, 0.0);
auxiliary_point[13] = getAuxiliaryPoint(v[3], center, 0.0, 1.0/2.0);
auxiliary_point[14] = getAuxiliaryPoint(v[3].copy().add(v[4].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[15] = getAuxiliaryPoint(v[4], center, 0.0, -1.0/2.0);
auxiliary_point[16] = getAuxiliaryPoint(v[4], center, 1.0/2.0, 0.0);
auxiliary_point[17] = getAuxiliaryPoint(v[4], center, 0.0, 1.0/2.0);
auxiliary_point[18] = getAuxiliaryPoint(v[4].copy().add(v[5].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[19] = getAuxiliaryPoint(v[5], center, 0.0, -1.0/2.0);
auxiliary_point[20] = getAuxiliaryPoint(v[5], center, 1.0/2.0, 0.0);
auxiliary_point[21] = getAuxiliaryPoint(v[5], center, 0.0, 1.0/2.0);
auxiliary_point[22] = getAuxiliaryPoint(v[5].copy().add(v[0].copy()).mult(0.5), center, 3.0/4.0, 0.0);
auxiliary_point[23] = getAuxiliaryPoint(v[0], center, 0.0, -1.0/2.0);
pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
pattern.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
pattern.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
pattern.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
pattern.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
pattern.quadraticVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y);
pattern.quadraticVertex(auxiliary_point[11].x, auxiliary_point[11].y, auxiliary_point[12].x, auxiliary_point[12].y);
pattern.quadraticVertex(auxiliary_point[13].x, auxiliary_point[13].y, auxiliary_point[14].x, auxiliary_point[14].y);
pattern.quadraticVertex(auxiliary_point[15].x, auxiliary_point[15].y, auxiliary_point[16].x, auxiliary_point[16].y);
pattern.quadraticVertex(auxiliary_point[17].x, auxiliary_point[17].y, auxiliary_point[18].x, auxiliary_point[18].y);
pattern.quadraticVertex(auxiliary_point[19].x, auxiliary_point[19].y, auxiliary_point[20].x, auxiliary_point[20].y);
pattern.quadraticVertex(auxiliary_point[21].x, auxiliary_point[21].y, auxiliary_point[22].x, auxiliary_point[22].y);
pattern.quadraticVertex(auxiliary_point[23].x, auxiliary_point[23].y, auxiliary_point[0].x, auxiliary_point[0].y);
pattern.endShape();
PShape decoratedHexagon = createShape(GROUP);
decoratedHexagon.addChild(hexagon);
decoratedHexagon.addChild(pattern);
return decoratedHexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP6M(){
tile = createShape(GROUP); // PShapeのグループを作る
PShape hexagon = decorateHexagon(); // 正六角形の生成
tile.addChild(hexagon); // グループに追加
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( (i%2 == 0 && j%4 == 0) || (i%2 == 1 && j%4 == 2) ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
noFill();
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}