ここでは、アイソヘドラルタイリングIH18（P31M）について、解説します。
Contents
IH18（P31M）
アイソヘドラルタイリングIH18（P31M）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したP31M群の基本図形の各辺の長さを調整したものを6つ組み合わせたものになっています。
IH18（P31M）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
IH18（P31M）の基本図形は正六角形で、上図のように点線で6つの凧型に分けると、各凧型は記事「基本図形の形を考える」で示したP31M群の基本図形の各辺の長さを調整したものであり、6つの凧型は点線で隣り合ったものがお互いに線対称になっています。
今回、各辺の中点と六角形の重心は、近接する三角格子点（黒点）の並びとなるように設定します。
IH18（P31M）の基本図形を並べる
このIH18（P31M）の基本図形をP31M群の対称性を保ちながら並べると、以下のような図形が得られます。
IH18（P31M）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(a_1, a_2, a_3\)のセットおよび辺\(b_1, b_2, b_3\)のセットはそれぞれ同じ辺となります。
辺\(a\)と辺\(b\)が重なっていますが、今回は辺\(a\)をその垂直二等分線に対して対称になるように変形し、辺\(b\)は変形した辺\(a\)と同じ形で上下反転したものにします。
※辺\(a\)と辺\(b\)の変形について
『辺\(a\)をその垂直二等分線に対して対称になるように変形する』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH18（P31M）の基本図形を記事「基本図形の形を考える」で示したP31M群の基本図形に分けて考えてみます。
このとき、辺\(a, b\)はそれぞれ２つの辺\(a’, b’\)に分けられます。辺\(a\)は辺\(a’\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（ここでは点線）に対して線対称になることになります。一方、辺\(a’\)と辺\(b’\)は異なる向きに重なっていますので、辺\(b’\)は変形した辺\(a’\)の形を上下左右反転した形に変形することになります。つまり、辺\(b\)は変形した辺\(a\)と同じ形で上下反転したものになります。
これらの変形により、隣り合う基本図形同士を重ねることなくP31G群の対称性に従って敷き詰めることができます。
ここでは、書籍「装飾パターンの法則」のp.96にあるIH18（P31M）の例を参考に、このルールに従ってIH18（P31M）の基本図形を下図のように変形してみました。
この変形した基本図形をP31M群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeTriangleVector(); // 三角格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP31M(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH18_P31M_transformation.jpg");
}
// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
base[0] = PVector.fromAngle(0.0);
base[1] = PVector.fromAngle(PI / 3);
}
// 三角格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].x); // 行の数
lattice = new PVector[col_num + 3][row_num + 1];
for (int i = 0; i < col_num + 3; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0].copy(), i * scalar);
v.add(PVector.mult(base[1].copy(), j * scalar));
if(j%4 == 0){
lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
} else {
lattice[i][j] = new PVector(v.x - (j/2+1) * scalar, v.y);
}
}
}
}
// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
PVector[] v = new PVector[6]; // 六角形の頂点
for(int i=0; i<6; i++){
v[i] = PVector.fromAngle(radians(150)-i*radians(60));
v[i].mult(2.0 / sqrt(3.0) * scalar);
}
// 六角形を変形する
PShape hexagon = createShape();
hexagon.beginShape();
PVector[] auxiliary_point = new PVector[3];
// 辺a1を変形する
hexagon.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, -sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, -sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[1].x, v[1].y);
// 辺b1は辺a1と同じ形を上下反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[2].x, v[2].y);
// 辺a2を辺a1と同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, -sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, -sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[3].x, v[3].y);
// 辺b2を辺b1と同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[4], 3.0/4.0, sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[4].x, v[4].y);
// 辺a3を辺a1と同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 1.0/4.0, -sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[4], v[5], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[4], v[5], 3.0/4.0, -sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[5].x, v[5].y);
// 辺b2を辺b1と同じ形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[5], v[0], 1.0/4.0, sqrt(3.0)/4.0);
auxiliary_point[1] = getAuxiliaryPoint(v[5], v[0], 1.0/2.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[5], v[0], 3.0/4.0, sqrt(3.0)/4.0);
hexagon.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
hexagon.vertex(auxiliary_point[1].x, auxiliary_point[1].y);
hexagon.vertex(auxiliary_point[2].x, auxiliary_point[2].y);
hexagon.vertex(v[0].x, v[0].y);
hexagon.endShape();
return hexagon;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP31M(){
tile = createShape(GROUP); // PShapeのグループを作る
PShape hexagon = transformHexagon(); // 変形した六角形の生成
tile.addChild(hexagon); // グループに追加
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%2 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}