IH17（CMM）

ここでは、アイソヘドラルタイリングIH17（CMM）について、解説します。

Contents

1 IH17（CMM）
- 1.1 IH17（CMM）の基本図形のサイズ
- 1.2 IH17（CMM）の基本図形を並べる
2 IH17（CMM）の基本図形の変形
- 2.1 ※辺\(b\)の変形について
3 プログラムコード

アイソヘドラルタイリングIH17（CMM）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものを4つ組み合わせたものになっています。また、今回は菱形格子の縦横比も調整しています。

IH17（CMM）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH17（CMM）の基本図形は六角形で、上図のように点線で4つの台形に分けると、各台形は記事「基本図形の形を考える」で示したCMM群の基本図形の各辺の長さを調整したものであり、互いに隣り合った2つの台形はそれぞれ点線でお互いに線対称になっています。

今回、各辺の中点と六角形の重心は、近接する菱形格子点（黒点）の並びとなるように設定します。また、上図の\(r_1,r_2\)は\(r_1+r_2\)が斜め方向に近接する菱形格子点間の高さとなるように設定します。

IH17（CMM）の基本図形を並べる

このIH17（CMM）の基本図形をCMM群の対称性を保ちながら並べると、以下のような図形が得られます。

IH17（CMM）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

4つの辺\(a_1, a_2, a_3, a_4\)および2つの辺\(b_1, b_2\)はそれぞれ同じ辺となります。

辺\(a\)は両側のラベルが同じで異なる向きに重なっていますので、中点に関して点対称な変形を行います。辺\(b\)は今回変形することができません。これについては下で説明します。これらの変形により、隣り合う基本図形同士を重ねることなくCMM群の対称性に従って敷き詰めることができます。

※辺\(b\)の変形について

『辺\(b\)が変形できない』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH17（CMM）の基本図形を記事「基本図形の形を考える」で示したCMM群の基本図形に分けて考えてみます。

このとき、辺\(b\)は２つの辺\(b′\)に分けられます。辺\(b\)は辺\(b′\)を異なる向きに2つ並べたものになっていますので、辺\(b\)の変形は垂直二等分線（ここでは横方向の点線）に対して線対称になることになります。一方、辺\(b′\)の両側のラベルは同じで同じ向きに重なっています。これは辺\(b′\)が変形できないことを示しています。つまり、辺\(b\)は変形できないことが分かります。

ここでは、書籍「装飾パターンの法則」のp.96にあるIH17（CMM）の例を参考に、このルールに従ってIH17（CMM）の基本図形を下図のように変形してみました。

この変形した基本図形をCMM群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は菱形格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCMM(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH17_CMM_transformation.jpg");
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.5, 0.75);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 2][row_num + 1];
  for (int i = 0; i < col_num + 2; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
    }
  }
}

// 六角形を変形する関数（基本図形）
PShape transformHexagon(){
  
  PVector[] v = new PVector[6]; // 六角形の頂点
  float r1, r2;
  r1 = 4.0/11.0 * scalar * base[1].y;
  r2 = 7.0/11.0 * scalar * base[1].y;

  v[0] = new PVector(-scalar * base[0].x, r1);
  v[1] = new PVector(0.0, r1 + 2.0 * r2);
  v[2] = new PVector(scalar * base[0].x, r1);
  v[3] = new PVector(scalar * base[0].x, -r1);
  v[4] = new PVector(0.0, -r1 - 2.0 * r2);
  v[5] = new PVector(-scalar * base[0].x, -r1);

  // 六角形を変形する
  PShape hexagon = createShape();
  hexagon.beginShape(); 
  PVector[] auxiliary_point = new PVector[3];
  // 辺a1を中点に対して点対称に変形する
  hexagon.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, -2.0/3.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, 0.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 2.0/3.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  hexagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[1].x, v[1].y);
  // 辺a2を辺a1と同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, 2.0/3.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, -2.0/3.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  hexagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[2].x, v[2].y);
  // 辺bは変形しない
  hexagon.vertex(v[3].x, v[3].y);
  // 辺a3を辺a1と同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 1.0/4.0, -2.0/3.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0/2.0, 0.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[3], v[4], 3.0/4.0, 2.0/3.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  hexagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[4].x, v[4].y);
  // 辺a4を辺a1と同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 1.0/4.0, 2.0/3.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[4], v[5], 1.0/2.0, 0.0);  
  auxiliary_point[2] = getAuxiliaryPoint(v[4], v[5], 3.0/4.0, -2.0/3.0);
  hexagon.quadraticVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y);
  hexagon.quadraticVertex(auxiliary_point[2].x, auxiliary_point[2].y, v[5].x, v[5].y);
  // 辺b2は変形しない
  hexagon.vertex(v[0].x, v[0].y);  
  
  hexagon.endShape();
  
  return hexagon;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileCMM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  PShape rectangle = transformHexagon(); // 変形した六角形の生成
  tile.addChild(rectangle); // グループに追加
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( (j%4 == 0 && i%2 == 0 ) || (j%4 == 2 && i%2 == 1 ) ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }

  // 格子点を描く
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}