IH11（P6）

  1. ホーム
  2. 壁紙アート
  3. アイソヘドラルタイリング
  4. IH11（P6）

ここでは、アイソヘドラルタイリングIH11（P6）について、解説します。

IH11（P6）

アイソヘドラルタイリングIH11（P6）の基本図形は以下のような形になります。

IH11（P6）の基本図形

これは、記事「基本図形の形を考える」で示したP6群の基本図形の各辺の長さを調整したものを6つ組み合わせたものになっています。

IH11（P6）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH11（P6）の基本図形のサイズ

IH161（P6）の基本図形は正六角形で、上図のように点線で6つの正三角形に分けると、各正三角形は記事「基本図形の形を考える」で示したP6群の基本図形の各辺の長さを調整したものであり、6つの正三角形は同じものになります。つまり、正六角形の辺はすべて同じ辺\(a\)となります。

今回、各辺\(a\)の中点と正六角形の重心は、近接する三角格子点（黒点）の並びとなるように設定します。また、正六角形の一辺の長さは近接する三角格子点の距離の\(2//sqrt{3}\)倍となるように設定します。

IH11（P6）の基本図形を並べる

このIH11（P6）の基本図形をP6群の対称性を保ちながら並べると、以下のような図形が得られます。

IH11（P6）による図形

IH11（P6）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

IH11（P6）の基本図形に対する辺のラベルと向き

全ての辺\(a\)が異なる向きに重なっています。つまり、全ての辺を中点に関して点対称な変形を行います。それにより、隣り合う基本図形同士を重ねることなくP6群の対称性に従って敷き詰めることができます。

ここでは、書籍「装飾パターンの法則」のp.95にあるIH11（P6）の例を参考に、このルールに従ってIH11（P6）の基本図形を下図のように変形してみました。

IH11（P6）の基本図形の変形

この変形した基本図形をP6群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。

IH11（P6）の変形した基本図形による図形

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH11_P6_transformation.jpg");
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 4][row_num + 1];
  for (int i = 0; i < col_num + 4; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+4)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
    }
  }
}

// 正六角形を変形する関数（基本図形）
PShape transformHexagon(){
  
  PVector[] v = new PVector[6]; // 正六角形の頂点
  
  for (int i=0; i<6; i++){
    v[i] = PVector.fromAngle(-i * PI / 3 + PI * 5.0/6.0).mult(scalar * 2.0 / sqrt(3.0));
  }

  // 正六角形を変形する
  PShape hexagon = createShape();
  hexagon.beginShape(); // 6点ずつの頂点から正六角形の頂点を作る
  PVector[] auxiliary_point = new PVector[2];
  // 辺aを中点に対して対象に変形する
  hexagon.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[1].x, v[1].y);
  // 辺bを辺aと同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[2].x, v[2].y);
  // 辺cを辺aと同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[3].x, v[3].y);
  // 辺dを辺aと同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[3], v[4], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[3], v[4], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[4].x, v[4].y);
  // 辺eを辺aと同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[4], v[5], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[4], v[5], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[5].x, v[5].y);
  // 辺fを辺aと同じ形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[5], v[0], 0.0, -1.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[5], v[0], 1.0, 1.0);
  hexagon.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, v[0].x, v[0].y);

  hexagon.endShape();
  
  return hexagon;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP6(){
  tile = createShape(GROUP); // PShapeのグループを作る
  PShape hexagon = transformHexagon(); // 変形した正六角形の生成
  tile.addChild(hexagon); // グループに追加
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }

  // 格子点を描画する
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}

コメントを残す