イスラムタイル

ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.30-33に紹介されている「イスラムタイル」をProcessingで再現してみましたので、その描き方とともに解説したいと思います。

Contents

1 イスラムタイル
2 描き方
3 プログラムコード

今回描いてみたイスラムタイルは以下のような図形になりました。

描き方

このイスラムタイルは壁紙群P4Gに分類されるものになります。イスラムタイルの基本図形は以下のような形状をしています。

この基本図形を準備することができれば、後はP4G群のルールに従って基本図形を並べていくことでイスラムタイルを描くことができます。

P4Gの基本図形を選ぶ

イスラムタイルの基本図形は、P4G群の基本図形を変形して作成します。そのためにまずP4G群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「P4G群の基本図形の形状」の節を参考にして、今回は直角二等辺三角形の形状を選びます。

P4G群の基本図形の変形

P4G群の基本図形を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。

辺\(a\)は同じ辺\(a\)が同じ向きに重なるので、変形できません。一方、辺\(b\)と辺\(c\)は異なる向きに重なっています。つまり、辺\(b\)を自由に変形したものを用意し、それを辺\(c\)の部分に反対向きに置きます。そうすると、隣り合う基本図形同士を重ねることなくP4G群の対称性に従って敷き詰めることができます。

辺\(b\)と辺\(c\)の変形

辺\(b\)と辺\(c\)の変形についてみていきます。まず辺\(b\)を下図のようにおきます（薄い線）。辺\(b\)の始点を原点\((0,0)\)として、辺\(b\)と平行に\(x\)軸（左向きを正）、辺\(b\)と垂直下向きに\(y\)軸をとります。辺\(b\)の長さを\(1\)とすると、辺\(b\)の終点の座標は\((1,0)\)となります。今回、辺\(b\)の変形を点\((4/5,2/5)\)を経由した折れ線（下図の黒線）にとります。

また、辺\(c\)の変形は辺\(b\)で変形したものを辺\(c\)の部分に反対向きに置くことで実現できます。これらを実施した結果、P4G群の基本図形はイスラムタイルの基本図形に変形することができます。

イスラムタイルを完成させる

P4G群の基本図形を変形した基本図形をP4G群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。

プログラムコード

最後に、プログラムコードを載せておきます。基本は別記事「渦巻き図形（P4G）」に記載しているプログラムコードのうち、makeRecurSquare関数をtransformIsoscelesRightTriangle関数に書き換え、makeTileP4G関数を図形の配色に注意して書き換えたものになります。

PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeSquareVector(); // 正方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP4G(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("P4G_islamic_tile.jpg");
}

// 正方格子を張るベクトルを生成する関数
void makeSquareVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = new PVector(0.0, 1.0);
}

// 正方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x, v.y);
    }
  }
}

// 直角二等辺三角形を変形する関数（基本図形）
PShape transformIsoscelesRightTriangle(){
  
  PVector[] v = new PVector[3]; // 直角二等辺三角形の頂点
  PShape isosceles_right_triangle = createShape();

  v[0] = base[0].copy().mult(-scalar / 2.0).add(base[1].copy().mult(scalar));
  v[1] = base[0].copy();
  v[1].mult(scalar / 2.0);
  v[2] = base[0].copy();
  v[2].mult(-scalar / 2.0);

  // 直角二等辺三角形を変形する
  isosceles_right_triangle.beginShape(); 
  PVector[] auxiliary_point = new PVector[2];
  // 辺aは変形できず、直線のみ。
  isosceles_right_triangle.vertex(v[0].x, v[0].y);
  isosceles_right_triangle.vertex(v[1].x, v[1].y);

  // 辺bをベジエ曲線で変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 4.0/5.0, 2.0/5.0);
  isosceles_right_triangle.vertex(auxiliary_point[0].x, auxiliary_point[0].y);  
  isosceles_right_triangle.vertex(v[2].x, v[2].y);

  // 辺cを辺bと同じ形で逆向きに変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[2], 4.0/5.0, 2.0/5.0);
  isosceles_right_triangle.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  
  isosceles_right_triangle.endShape(CLOSE);
  
  return isosceles_right_triangle;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP4G(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int j=0; j<2; j++){
    for(int i=0; i<4; i++){

      noStroke();
      if( (i % 2 == 0 && j == 0 ) 
        || (i % 2 == 1 && j == 1 ) 
      ){
        fill(0,0,0);
      } else {
        fill(255,255,255);
      }      

      PShape isosceles_right_triangle = transformIsoscelesRightTriangle(); // 直角二等辺三角形の生成
      isosceles_right_triangle.scale(1, pow(-1,j)); // 直角二等辺三角形の反転
      isosceles_right_triangle.rotate(i*radians(90)); // 直角二等辺三角形の回転
      PVector direction = PVector.fromAngle(i*radians(90)); // 直角二等辺三角形の移動方向
      direction.mult(scalar / 2.0);
      isosceles_right_triangle.translate(direction.x + j*scalar, direction.y + j*scalar); // 直角二等辺三角形の位置を調整
      tile.addChild(isosceles_right_triangle); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2==0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画 
      }
    }
  }
}