IH89（P31M）

ここでは、アイソヘドラルタイリングIH89（P31M）について、解説します。

Contents

1 IH89（P31M）
- 1.1 IH89（P31M）の基本図形のサイズ
- 1.2 IH89（P31M）の基本図形を並べる
2 IH89（P31M）の基本図形の変形
3 IH89（P31M）の基本図形に模様をつける
4 プログラムコード

アイソヘドラルタイリングIH89（P31M）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したP3M1群の基本図形の各辺の長さを調整したもの（IH38（P31M）の基本図形）を３つ組み合わせたものになっています。

IH89（P31M）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

IH89（P31M）の基本図形は正三角形の形状をしています。正三角形の各頂点、および各辺の中点がそれぞれ三角格子点（黒点）と一致するようにとります。なお、正三角形を図のように点線で分けると、3つのP31M群の基本図形となります。

IH89（P31M）の基本図形を並べる

このIH89（P31M）の基本図形をP31M群の対称性を保ちながら並べると、以下のような図形が得られます。

IH89（P31M）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

正三角形の3つの辺はすべて同じ辺となります。

辺\(a\)は両側のラベルが同じで向きも同じになっています。これは、辺\(a\)が変形できないことを示しています。つまり、IH89（P31M）の基本図形は変形することができないことになります。

IH89（P31M）の基本図形に模様をつける

IH89（P31M）の基本図形は変形できませんので、代わりに模様をつけてみます。

IH89（P31M）の基本図形は以下の図のように正三角形の重心（赤三角点）を中心とした120°回転について対称な図形になります。

ここでは、この対称性を考慮して、書籍「装飾パターンの法則」のp.107にあるIH89（P31M）の例を参考に、以下のように模様を描いてみました。

この模様を描いた基本図形をP31M群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP31M(); // タイルを生成
  drawTiling(); // タイリングを描画

  save("IH89_P31M_decoration.jpg");
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = PVector.fromAngle(0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0].copy(), i * scalar); 
      v.add(PVector.mult(base[1].copy(), j * scalar));
      if(j%4 == 0){
        lattice[i][j] = new PVector(v.x - (j/2) * scalar, v.y);
      } else {
        lattice[i][j] = new PVector(v.x - (j/2+1) * scalar, v.y);
      }
    }
  }
}

// 三角形に模様を描く関数（基本図形）
PShape decorateTriangle(){
  
  PVector[] v = new PVector[3]; // 三角形の頂点

  v[0] = new PVector(0.0, 0.0);
  v[1] = base[0].copy().mult(2.0 * scalar);
  v[2] = new PVector(scalar, -base[1].y * scalar * 2.0); 

  // 三角形を描く
//  fill(255,255,255);
  noFill();
  PShape tri = createShape();
  tri.beginShape(TRIANGLES); // 3点ずつの頂点から直角三角形を作る
  for (int i=0; i<3; i++){
    tri.vertex(v[i].x, v[i].y);
  }  
  tri.endShape();
  
  // 模様を描く
  fill(200,0,0,128);
  PVector center = new PVector((v[1].x+v[2].x)/2.0 * 2.0/3.0, (v[1].y+v[2].y)/2.0 * 2.0/3.0);
  PShape pattern = createShape();
  pattern.beginShape();
  PVector[] auxiliary_point = new PVector[6]; 
  auxiliary_point[0] = getAuxiliaryPoint(v[0], center, 2.0/3.0, 0.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], center, 1.0/8.0, -1.0/3.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], center, 2.0/3.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], center, 1.0/8.0, -1.0/3.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], center, 2.0/3.0, 0.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[0], center, 1.0/8.0, -1.0/3.0);
  pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  pattern.quadraticVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y); 
  pattern.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
  pattern.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[0].x, auxiliary_point[0].y);
  pattern.endShape();
  
  PShape decoratedTri = createShape(GROUP);
  decoratedTri.addChild(tri);
  decoratedTri.addChild(pattern);

  return decoratedTri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP31M(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int j=0; j<2; j++){
    PShape tri = decorateTriangle(); // 三角形の生成
    tri.scale(1, pow(-1,j)); // x軸に関して鏡映
    tile.addChild(tri); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
  
  // 格子点を描く
  noFill();
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}