IH77（P6M）

ここでは、アイソヘドラルタイリングIH77（P6M）について、解説します。

Contents

1 IH77（P6M）
- 1.1 IH77（P6M）の基本図形のサイズ
- 1.2 IH77（P6M）の基本図形を並べる
2 IH77（P6M）の基本図形の変形
3 IH77（P6M）の基本図形に模様をつける
4 プログラムコード

アイソヘドラルタイリングIH77（P6M）の基本図形は以下のような形になります。

これは、記事「基本図形の形を考える」で示したP6M群の基本図形になっています。

IH77（P6M）の基本図形のサイズ

この基本図形の各辺に以下の図のように、ラベルを振ります。

今回、基本図形は２つの頂角がそれぞれ30°と60°をもつ直角三角形の形状をしています。直角三角形の30°と90°をもつ頂点はそれぞれ三角格子点（黒点）と一致するようにとります。また、60°をもつ頂点は近接する3つの格子点で作られる正三角形の重心（赤点）と一致するようにとります。

IH77（P6M）の基本図形を並べる

このIH77（P6M）の基本図形をP6M群の対称性を保ちながら並べると、以下のような図形が得られます。

IH77（P6M）の基本図形の変形

基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。

辺\(a,b,c\)はそれぞれ両側のラベルが同じで同じ向きに重なっています。つまり、辺\(a,b,c\)は3辺とも変形できないことがわかります。これは、IH77（P6M）の基本図形が変形できないことを示しています。

IH77（P6M）の基本図形に模様をつける

IH77（P6M）の基本図形は変形できませんので、代わりに模様をつけてみます。

IH77（P6M）の基本図形自身には特に対称性がありませんので、模様は自由に描くことができます。ここでは、書籍「装飾パターンの法則」のp.105にあるIH77（P6M）の例を参考に、以下のように模様を描いてみました。

この模様を描いた基本図形をP6M群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は三角格子点も示しています。

プログラムコード

今回の図形を作成するためのプログラムコードを示します。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6M(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("IH77_P6M_decoration.jpg");
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
    }
  }
}

// 三角形に模様を描く関数（基本図形）
PShape decorateTriangle(){
  
  PVector[] v = new PVector[3]; // 三角形の頂点
 
  v[0] = new PVector(0.0,0.0);
  v[1] = PVector.fromAngle(PI / 6.0);
  v[1].mult(2.0 * scalar / sqrt(3.0));  
  v[2] = new PVector(1.0,0.0);
  v[2].mult(scalar);

  // 三角形を描く
//  fill(255,255,255);
  noFill();
  PShape tri = createShape();
  tri.beginShape(TRIANGLES); // 3点ずつの頂点から直角三角形を作る
  for (int i=0; i<3; i++){
    tri.vertex(v[i].x, v[i].y);
  }  
  tri.endShape();
  
  // 模様を描く
  fill(200,0,0,128);
//  PVector center = new PVector((v[1].x+v[2].x)/2.0, (v[1].y+v[2].y)/2.0);
  PShape pattern = createShape();
  pattern.beginShape();
  PVector[] auxiliary_point = new PVector[4]; 
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, -1.0/10.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 0.0, -3.0/20.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 1.0/8.0, -2.0/5.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 5.0/8.0, -1.0/10.0);
  pattern.vertex(auxiliary_point[0].x, auxiliary_point[0].y);
  pattern.bezierVertex(auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y, auxiliary_point[3].x, auxiliary_point[3].y); 
  pattern.endShape(CLOSE);
  
  PShape decoratedTri = createShape(GROUP);
  decoratedTri.addChild(tri);
  decoratedTri.addChild(pattern);

  return decoratedTri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP6M(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<6; i++){
    PShape positiveTri = createShape(GROUP); // 直角三角形を2つ合わせて正三角形を生成
    for (int j=0; j<2; j++){
      PShape rightTri = decorateTriangle(); // 直角三角形の生成
      rightTri.scale(1, pow(-1, j)); // x軸を中心に鏡映
      positiveTri.addChild(rightTri);
    }
    positiveTri.rotate(PI * i / 3.0); // 60度回転
    tile.addChild(positiveTri); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }

  // 格子点を描く
  noFill();
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      circle(lattice[i][j].x, lattice[i][j].y, 10);
    }
  }
}