ここでは、アイソヘドラルタイリングIH66（PMG）について、解説します。
Contents
IH66（PMG）
アイソヘドラルタイリングIH66（PMG）の基本図形は以下のような形になります。
これは、記事「基本図形の形を考える」で示したPMG群の基本図形（五角形）の各辺を調整したものを2つ組み合わせたものになっています。
IH66（PMG）の基本図形のサイズ
この基本図形の各辺に以下の図のように、ラベルを振ります。
今回、基本図形は長方形の形状をしています。この長方形の各頂点がそれぞれ長方格子点（黒点）と一致するようにとります。なお、長方形を図のように点線で分けると、2つのPMG群の基本図形（五角形を調整したもの）となります。
IH66（PMG）の基本図形を並べる
このIH66（PMG）の基本図形をPMG群の対称性を保ちながら並べると、以下のような図形が得られます。
IH66（PMG）の基本図形の変形
基本図形の変形を行うために、基本図形の各辺にラベルをふって、隣り合う基本図形との辺の対応関係を見てみます。
辺\(b\)と辺\(b′\)は同じ辺となります。
辺\(a\)と辺\(c\)が重なっていますが、今回、向きは両方に取っています。これは、辺\(a\)をその垂直二等分線に対して線対称になるように変形し、辺\(c\)は変形した辺\(a\)を上下反転した形状に変形します。辺\(b\)は両側のラベルが同じで異なる向きに重なっています。つまり、辺\(b\)はその中点に対して点対称に変形することができます。それにより、隣り合う基本図形同士を重ねることなくPMG群の対称性に従って敷き詰めることができます。
※辺\(a\)と辺\(c\)の変形について
『辺\(a\)をその垂直二等分線に対して線対称になるように変形する』と説明しましたが、これについてもう少し詳しく見てみます。そのために、以下のように、IH66（PMG）の基本図形を記事「基本図形の形を考える」で示したPMG群の基本図形に分けて考えてみます。
このとき、辺\(a\)は２つの辺\(a′\)、辺\(c\)は２つの辺\(c′\)にそれぞれ分けられます。辺\(a\)は辺\(a′\)を異なる向きに2つ並べたものになっていますので、辺\(a\)の変形は垂直二等分線（上図の点線）に対して線対称になります。一方、辺\(a′\)と辺\(c′\)が異なる向きに重なっています。これは辺\(a′\)を変形し、辺\(c′\)は変形した辺\(a′\)を上下左右反転した形状に変形することを表しています。つまり、辺\(c\)は変形した辺\(a\)を上下反転した形状に変形すればよいことが分かります。
ここでは、書籍「装飾パターンの法則」のp.103にあるIH66（PMG）の例を参考に、このルールに従ってIH66（PMG）の基本図形を下図のように変形してみました。
この変形した基本図形をPMG群の対称性を考慮して並べていくと、下図のような図形を得ることができます。なお、今回は長方格子点も示しています。
プログラムコード
今回の図形を作成するためのプログラムコードを示します。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeRectVector(); // 長方格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTilePMG(); // タイルを生成
drawTiling(); // タイリングを描画
save("IH66_PMG_transformation.jpg");
}
// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 2.0);
base[1].mult(0.6);
}
// 長方格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 1][row_num + 1];
for (int i = 0; i < col_num + 1; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
}
}
}
// 四角形を変形する関数（基本図形）
PShape transformRectangle(){
PVector[] v = new PVector[4]; // 四角形の頂点
v[0] = base[1].copy().mult(scalar);
v[1] = v[0].copy();
v[1].add(base[0].copy().mult(scalar));
v[2] = base[0].copy().mult(scalar);
v[3] = new PVector(0.0, 0.0);
// 四角形を変形する
PShape rect = createShape();
rect.beginShape();
PVector[] auxiliary_point = new PVector[11];
// 辺aは垂直二等分線に対して線対称に変形する
rect.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/8.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/8.0, 1.0/16.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 1.0/4.0, 1.0/16.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 3.0/8.0, 1.0/16.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 7.0/16.0, 1.0/8.0);
auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 1.0/2.0, -1.0/16.0);
auxiliary_point[6] = getAuxiliaryPoint(v[0], v[1], 9.0/16.0, 1.0/8.0);
auxiliary_point[7] = getAuxiliaryPoint(v[0], v[1], 5.0/8.0, 1.0/16.0);
auxiliary_point[8] = getAuxiliaryPoint(v[0], v[1], 3.0/4.0, 1.0/16.0);
auxiliary_point[9] = getAuxiliaryPoint(v[0], v[1], 7.0/8.0, 1.0/16.0);
auxiliary_point[10] = getAuxiliaryPoint(v[0], v[1], 7.0/8.0, 0.0);
rect.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
rect.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
rect.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
rect.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
rect.bezierVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y, v[1].x, v[1].y);
// 辺bは中点に対して点対称に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/8.0, -1.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 7.0/16.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 0.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 9.0/16.0, 0.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 7.0/8.0, 1.0/3.0);
rect.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
rect.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, v[2].x, v[2].y);
// 辺cは辺aと同じ形で上下反転した形に変形する
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/8.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/8.0, -1.0/16.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, -1.0/16.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 3.0/8.0, -1.0/16.0);
auxiliary_point[4] = getAuxiliaryPoint(v[2], v[3], 7.0/16.0, -1.0/8.0);
auxiliary_point[5] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 1.0/16.0);
auxiliary_point[6] = getAuxiliaryPoint(v[2], v[3], 9.0/16.0, -1.0/8.0);
auxiliary_point[7] = getAuxiliaryPoint(v[2], v[3], 5.0/8.0, -1.0/16.0);
auxiliary_point[8] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, -1.0/16.0);
auxiliary_point[9] = getAuxiliaryPoint(v[2], v[3], 7.0/8.0, -1.0/16.0);
auxiliary_point[10] = getAuxiliaryPoint(v[2], v[3], 7.0/8.0, 0.0);
rect.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
rect.quadraticVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y);
rect.quadraticVertex(auxiliary_point[5].x, auxiliary_point[5].y, auxiliary_point[6].x, auxiliary_point[6].y);
rect.quadraticVertex(auxiliary_point[7].x, auxiliary_point[7].y, auxiliary_point[8].x, auxiliary_point[8].y);
rect.bezierVertex(auxiliary_point[9].x, auxiliary_point[9].y, auxiliary_point[10].x, auxiliary_point[10].y, v[3].x, v[3].y);
// 辺b'は辺bと同じ形に変形する（向きに注意）
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/8.0, 1.0/3.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 7.0/16.0, 0.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 1.0/2.0, 0.0);
auxiliary_point[3] = getAuxiliaryPoint(v[3], v[0], 9.0/16.0, 0.0);
auxiliary_point[4] = getAuxiliaryPoint(v[3], v[0], 7.0/8.0, -1.0/3.0);
rect.bezierVertex(auxiliary_point[0].x, auxiliary_point[0].y, auxiliary_point[1].x, auxiliary_point[1].y, auxiliary_point[2].x, auxiliary_point[2].y);
rect.bezierVertex(auxiliary_point[3].x, auxiliary_point[3].y, auxiliary_point[4].x, auxiliary_point[4].y, v[0].x, v[0].y);
rect.endShape();
return rect;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTilePMG(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
PShape rectangle = transformRectangle(); // 変形した四角形の生成
rectangle.scale(1,pow(-1,i)); // 反転
rectangle.translate(i*scalar, 0.0); // 四角形の位置を調整
tile.addChild(rectangle); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
// 格子点を描く
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
circle(lattice[i][j].x, lattice[i][j].y, 10);
}
}
}