ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.84-89に紹介されている「ワタリドリの模様その２」をProcessingで簡略化した形で再現してみましたので、その描き方とともに紹介したいと思います。
ワタリドリの模様その２
今回描いてみたワタリドリの模様その２は以下のような図形になりました。
描き方
このワタリドリの模様その２は壁紙群PGGに分類されるものになります。ワタリドリの模様その２の基本図形は以下のような形状をしています。
この基本図形を準備することができれば、後はPGG群のルールに従って基本図形を並べていくことでワタリドリの模様その２を描くことができます。
PGG群の基本図形を選ぶ
ワタリドリの模様その２の基本図形は、PGG群の基本図形を変形して作成します。そのためにまずPGG群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「PGG群の基本図形の形状」の節を参考にして、今回はやじりの形状を選びます。
やじり形状の準備
今回の「ワタリドリの模様その２」を描くための一番のポイントはこのやじり形状をどのように準備していくかということだと思いますので、もう少し解説します。
- 一般格子を上図のような配置（4つの黒点）で準備します。
- 記事「基本図形の形を考える」の「PGG群の基本図形の形状」の節で記載しているように、PGG群の基本図形の2つの辺の中点はそれぞれ隣り合った一般格子上の点と一致します。このことを利用して、以下やじり形状を準備していきます。これらの一般格子点を上図のようにA,B,C,Dとします。
- 長方形ABCDの内部に適当な点を選びます。この点を点3としておきます。
- 点0を線分A0と線分C3の長さが等しく、また∠AB0＋∠CD3=180°となるようにとります。
- 点0を端点にとり、点Aを中点とするような線分を描き、もう一つの端点を点1とします。
- 点1を端点にとり、点Bを中点とするような線分を描き、もう一つの端点を点2とします。
- 最後に点2と点3、点3と点0を結ぶと、四角形0123が求めたいやじりの形状になります。
PGG群の基本図形の変形
PGG群の基本図形（やじり形状）を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。
辺\(a,b\)についてそれぞれ両側のラベルが同じで向きが異なっていますので、中点に関して点対称な変形を行います。一方、辺\(c,d\)はそれぞれ同じ向きに重なっています。つまり、辺\(c\)を適当に変形したあと、辺\(d\)は、変形した辺\(c\)を上下反転した形状に変形します。そうすると、隣り合う基本図形同士を重ねることなくPGG群の対称性に従って敷き詰めることができます。
各辺の変形
実際の各辺について、今回は以下の図のように変形しています。
なお、辺\(c\)の変形は自由にできますが、今回は中点に関して点対称な変形を行っています。
これらの変形を実施した結果、PGG群の基本図形（やじり形状）はワタリドリの模様その２の基本図形に変形することができます。
プログラムコード
PGG群の基本図形を変形した基本図形をPGG群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeRectVector(); // 長方格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTilePGG(); // タイルを生成
drawTiling(); // タイリングを描画
save("PGG_migratory_bird.jpg");
}
// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI / 2.0);
base[1].mult(1.8);
}
// 長方格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / base[1].y); // 行の数
lattice = new PVector[col_num + 1][row_num + 2];
for (int i = 0; i < col_num + 1; i++){
for (int j = 0; j < row_num + 2; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
}
}
}
// やじり形状を変形する関数（基本図形）
PShape transformArrowhead(){
PVector[] lattice_v = new PVector[4]; // 長方形の頂点
PVector[] v = new PVector[4]; // やじりの頂点
lattice_v[0] = base[0].copy();
lattice_v[0].sub(base[1]);
lattice_v[0].mult(-scalar / 2.0);
lattice_v[1] = base[0].copy();
lattice_v[1].add(base[1]);
lattice_v[1].mult(scalar / 2.0);
lattice_v[2] = base[0].copy();
lattice_v[2].sub(base[1]);
lattice_v[2].mult(scalar / 2.0);
lattice_v[3] = base[0].copy();
lattice_v[3].add(base[1]);
lattice_v[3].mult(-scalar / 2.0);
PVector auxiliary = new PVector(base[0].x * 3.0/5.0, base[1].y * 7.0 /10.0);
auxiliary.mult(scalar);
v[0] = new PVector(scalar - auxiliary.x, auxiliary.y);
v[0].mult(-1.0);
v[0].add(lattice_v[0].copy());
v[1] = new PVector(scalar - auxiliary.x, auxiliary.y);
v[1].add(lattice_v[0].copy());
v[2] = new PVector(auxiliary.x, -auxiliary.y);
v[2].add(lattice_v[1].copy());
v[3] = auxiliary.copy();
v[3].add(lattice_v[3].copy());
// ワタリドリを描く
PShape arrowhead = createShape();
arrowhead.beginShape();
PVector[] auxiliary_point = new PVector[6];
// 辺aの変形
arrowhead.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 3.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 4.0/20.0, 1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 9.0/20.0, 1.0/10.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 11.0/20.0, -1.0/10.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 16.0/20.0, -1.0/20.0);
auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 17.0/20.0, 0.0);
for(int i=0; i<6; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[1].x, v[1].y);
// 辺bの変形
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 3.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 4.0/20.0, -1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 8.0/20.0, -2.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 12.0/20.0, 2.0/20.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 16.0/20.0, 1.0/20.0);
auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 17.0/20.0, 0.0);
for(int i=0; i<6; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[2].x, v[2].y);
// 辺cの変形
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/4.0, -1.0/10.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 11.0/20.0, -3.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[2], v[3], 9.0/20.0, 3.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[2], v[3], 3.0/4.0, 1.0/10.0);
for(int i=0; i<4; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[3].x, v[3].y);
// 辺dは辺cの変形を上下反転したもの
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/4.0, 1.0/10.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 11.0/20.0, 3.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 9.0/20.0, -3.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[3], v[0], 3.0/4.0, -1.0/10.0);
for(int i=0; i<4; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[0].x, v[0].y);
arrowhead.endShape();
return arrowhead;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTilePGG(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
for(int j=0; j<2; j++){
noStroke();
if( j % 2 == 0 ){
fill(0,0,0);
} else {
fill(255,255,255);
}
PShape rectangle = transformArrowhead(); // 変形したやじり形状の生成
rectangle.scale(pow(-1,i),pow(-1,j)); // 変形したやじり形状の反転
rectangle.translate((0.5-j)*scalar, (0.5-i)*scalar*base[1].y); // 変形したやじり形状の位置を調整
tile.addChild(rectangle); // グループに追加
}
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
if( i%2 == 0 && j%2 == 0 ){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}
}