トビウオの模様その２

ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.144-149に紹介されている「トビウオの模様その２」をProcessingで再現してみましたので、その描き方とともに解説したいと思います。

Contents

1 トビウオの模様その２
2 描き方
- 2.1 PGGの基本図形を選ぶ
- 2.2 PGG群の基本図形の変形
3 プログラムコード

今回描いてみたトビウオの模様その２は以下のような図形になりました。

描き方

このトビウオの模様その２は壁紙群PGGに分類されるものになります。トビウオの模様その２の基本図形は以下のような形状をしています。

この基本図形を準備することができれば、後はPGG群のルールに従って基本図形を並べていくことでトビウオの模様その２を描くことができます。

PGGの基本図形を選ぶ

トビウオの模様その２の基本図形は、PGG群の基本図形を変形して作成します。そのためにまずPGG群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「PGG群の基本図形の形状」の節を参考にして、今回は二等辺三角形の形状を選びます。

なお、この三角形の3つの頂点および底辺の中点は、互いに隣り合った長方格子点上に乗っています。

PGG群の基本図形の変形

PGG群の基本図形を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。

辺\(a\)についてそれぞれ両側のラベルが同じで向きが異なっていますので、中点に関して点対称な変形を行います。一方、辺\(b,c\)はそれぞれ同じ向きに重なっています。つまり、辺\(b\)を適当に変形したあと、辺\(c\)は、変形した辺\(b\)を上下反転した形状に変形します。そうすると、隣り合う基本図形同士を重ねることなくPGG群の対称性に従って敷き詰めることができます。

各辺の変形

実際の各辺について、今回は以下の図のように変形しています。

辺\(c\)は辺\(b\)の変形を上下反転したものになります。

これらの変形を実施した結果、PGG群の基本図形はトビウオの模様その２の基本図形に変形することができます。

プログラムコード

PGG群の基本図形を変形した基本図形をPGG群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePGG(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("PGG_flying_fish.jpg");
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 2.0);
  base[1].mult(1.2);
}

// 長方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+1)*scalar), v.y);
    }
  }
}

// 二等辺三角形を変形する関数（基本図形）
PShape transformTriangle(){
  
  PVector[] v = new PVector[3]; // 二等辺三角形の頂点

  v[0] = base[0].copy();
  v[0].sub(base[1]);
  v[0].mult(-scalar / 2.0);
  v[1] = base[0].copy();
  v[1].mult(scalar * 2.0);
  v[1].add(v[0].copy());  
  v[2] = base[0].copy();
  v[2].sub(base[1]);
  v[2].mult(scalar / 2.0);

  // 二等辺三角形を描く
  PShape tri = createShape();
  tri.beginShape(); 
  PVector[] auxiliary_point = new PVector[7];
  // 辺aの変形
  tri.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/6.0, -1.0/10.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 7.0/15.0, -1.0/10.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 8.0/15.0, 1.0/10.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 5.0/6.0, 1.0/10.0);
  for(int i=0; i<4; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[1].x, v[1].y); 
  // 辺bの変形
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/7.0, -2.0/21.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 8.0/21.0, -4.0/21.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 8.0/21.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 3.0/7.0, 1.0/7.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 13.0/21.0, 2.0/21.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 15.0/21.0, -1.0/7.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[1], v[2], 19.0/21.0, 0.0);
  for(int i=0; i<7; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[2].x, v[2].y); 
  // 辺cを辺bを上下に反転させた形に変形する
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/7.0, 2.0/21.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 8.0/21.0, 4.0/21.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 8.0/21.0, 0.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 3.0/7.0, -1.0/7.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 13.0/21.0, -2.0/21.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[2], v[0], 15.0/21.0, 1.0/7.0);
  auxiliary_point[6] = getAuxiliaryPoint(v[2], v[0], 19.0/21.0, 0.0);
  for(int i=0; i<7; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[0].x, v[0].y); 

  tri.endShape();
  
  return tri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTilePGG(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    for(int j=0; j<2; j++){

      noStroke();
      if( j % 2 == 0 ){
        fill(0,0,0);
      } else {
        fill(255,255,255);
      }
      
      PShape tri = transformTriangle(); // 変形された二等辺三角形の生成
      tri.scale(pow(-1,i),pow(-1,j)); // 二等辺三角形の反転
      tri.translate((0.5-j)*scalar, (0.5-i)*scalar*base[1].y); // 二等辺三角形の位置を調整
      tile.addChild(tri); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}