ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.78-80に紹介されている「ワタリドリの模様」をProcessingで簡略化した形で再現してみましたので、その描き方とともに紹介したいと思います。
ワタリドリの模様
今回描いてみたワタリドリの模様は以下のような図形になりました。
描き方
このワタリドリの模様は壁紙群P2に分類されるものになります。ワタリドリの模様の基本図形は以下のような形状をしています。
この基本図形を準備することができれば、後はP2群のルールに従って基本図形を並べていくことでワタリドリの模様を描くことができます。
P2群の基本図形を選ぶ
ワタリドリの模様の基本図形は、P2群の基本図形を変形して作成します。そのためにまずP2群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「P2群の基本図形の形状」の節を参考にして、今回はやじりの形状を選びます。
やじり形状の準備
今回の「ワタリドリの模様」を描くための一番のポイントはこのやじり形状をどのように準備していくかということだと思いますので、もう少し解説します。
- 一般格子を上図のような配置（4つの黒点）で準備します。
- 記事「基本図形の形を考える」の「P2群の基本図形の形状」の節で記載しているように、P2群の基本図形の１つの辺の中点は一般格子上の点と一致し、また別の3つの辺の中点は隣り合う一般格子点同士の中点（上図赤点）になっています。このことを利用して、以下やじり形状を準備していきます。これらの点を上図のようにA,B,C,Dとします。
- 平行四辺形ABCDの内部に適当な点を選びます。この点を点\(3\)としておきます。
- 点\(3\)を端点にとり、点Dを中点とするような線分を描き、もう一つの端点を点\(0\)とします。
- 点\(0\)を端点にとり、点Aを中点とするような線分を描き、もう一つの端点を点\(1\)とします。
- 点\(1\)を端点にとり、点Bを中点とするような線分を描き、もう一つの端点を点\(2\)とします。
- 最後に点\(2\)と点\(3\)を結ぶと、四角形\(0123\)が求めたいやじりの形状になります。
P2群の基本図形の変形
P2群の基本図形（やじり形状）を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。
4つのすべての辺\(a,b,c,d\)についてそれぞれ両側のラベルが同じで向きが異なっていますので、中点に関して点対称な変形を行います。そうすると、隣り合う基本図形同士を重ねることなくP2群の対称性に従って敷き詰めることができます。
各辺の変形
実際の各辺について、今回は以下の図のように変形しています。
これらの変形を実施した結果、P2群の基本図形（やじり形状）はワタリドリの模様の基本図形に変形することができます。
プログラムコード
P2群の基本図形を変形した基本図形をP2群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。
PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ
void setup(){
size(1000, 1000, P2D);
noFill();
scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
makeGeneralVector(); // 一般格子を張るベクトルの生成
makeLattice(); // 格子点ベクトルを生成
makeTileP2(); // タイルを生成
drawTiling(); // タイリングを描画
save("P2_migratory_bird.jpg");
}
// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
base[0] = new PVector(1.0, 0.0);
base[1] = PVector.fromAngle(PI * 7.0 / 12.0);
base[1].mult(0.9);
}
// 一般格子を生成する関数
void makeLattice(){
int row_num = ceil(col_num / abs(base[1].x)); // 行の数
lattice = new PVector[col_num + 4][row_num + 1];
for (int i = 0; i < col_num + 4; i++){
for (int j = 0; j < row_num + 1; j++){
PVector v = PVector.mult(base[0], i * scalar);
v.add(PVector.mult(base[1], j * scalar));
lattice[i][j] = new PVector(v.x % ((col_num+4)*scalar) - 2.0 * scalar, v.y-scalar * base[1].y);
}
}
}
// やじり形状をワタリドリに変形する関数（基本図形）
PShape transformArrowhead(){
PVector a_center, b_center, c_center, d_center; // 平行四辺形の頂点
PVector[] v = new PVector[4]; // やじりの頂点
a_center = base[1].copy();
a_center.mult(scalar / 2.0);
b_center = base[0].copy();
b_center.add(base[1]);
b_center.mult(scalar / 2.0);
c_center = base[0].copy();
c_center.mult(scalar / 2.0);
d_center = new PVector(0.0,0.0);
v[3] = base[0].copy().mult(scalar * 7.0 / 24.0);
v[3].add(base[1].copy().mult(scalar / 6.0));
v[0] = d_center.copy().sub(v[3].copy()).mult(2.0);
v[0].add(v[3].copy());
v[1] = a_center.copy().sub(v[0].copy()).mult(2.0);
v[1].add(v[0].copy().sub(d_center.copy()));
v[2] = b_center.copy().sub(v[1].copy()).mult(2.0);
v[2].add(v[1].copy().sub(d_center.copy()));
// ワタリドリを描く
PShape arrowhead = createShape();
arrowhead.beginShape();
PVector[] auxiliary_point = new PVector[6];
// 辺aの変形
arrowhead.vertex(v[0].x, v[0].y);
auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 3.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 4.0/20.0, 1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 9.0/20.0, 1.0/10.0);
auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 11.0/20.0, -1.0/10.0);
auxiliary_point[4] = getAuxiliaryPoint(v[0], v[1], 16.0/20.0, -1.0/20.0);
auxiliary_point[5] = getAuxiliaryPoint(v[0], v[1], 17.0/20.0, 0.0);
for(int i=0; i<6; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[1].x, v[1].y);
// 辺bの変形
auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 3.0/20.0, 0.0);
auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 4.0/20.0, -1.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 8.0/20.0, -2.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 12.0/20.0, 2.0/20.0);
auxiliary_point[4] = getAuxiliaryPoint(v[1], v[2], 16.0/20.0, 1.0/20.0);
auxiliary_point[5] = getAuxiliaryPoint(v[1], v[2], 17.0/20.0, 0.0);
for(int i=0; i<6; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[2].x, v[2].y);
// 辺cの変形
auxiliary_point[0] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, -1.0/10.0);
auxiliary_point[1] = getAuxiliaryPoint(v[2], v[3], 1.0/2.0, 1.0/10.0);
for(int i=0; i<2; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[3].x, v[3].y);
// 辺dの変形
auxiliary_point[0] = getAuxiliaryPoint(v[3], v[0], 1.0/4.0, 1.0/10.0);
auxiliary_point[1] = getAuxiliaryPoint(v[3], v[0], 11.0/20.0, 3.0/20.0);
auxiliary_point[2] = getAuxiliaryPoint(v[3], v[0], 9.0/20.0, -3.0/20.0);
auxiliary_point[3] = getAuxiliaryPoint(v[3], v[0], 3.0/4.0, -1.0/10.0);
for(int i=0; i<4; i++){
arrowhead.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
}
arrowhead.vertex(v[0].x, v[0].y);
arrowhead.endShape();
return arrowhead;
}
// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
PVector start,
PVector end,
float parallel_size,
float vertical_size
){
PVector dir_parallel = end.copy().sub(start.copy());
PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
return auxiliary_point;
}
// タイルを生成する関数
void makeTileP2(){
tile = createShape(GROUP); // PShapeのグループを作る
for(int i=0; i<2; i++){
noStroke();
if( i % 2 == 0 ){
fill(255,255,255);
} else {
fill(0,0,0);
}
PShape arrowhead = transformArrowhead(); // 変形したやじり形状の生成
arrowhead.rotate(PI * i); // 180度回転
tile.addChild(arrowhead); // グループに追加
}
}
// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
// background(255);
for (int i=0; i<lattice.length; i++){
for (int j=0; j<lattice[0].length; j++){
tile.resetMatrix();
tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
shape(tile); // タイルを描画
}
}
}