トビウオの模様

  1. ホーム
  2. エッシャーに挑戦！
  3. トビウオの模様

ここでは、書籍「M.C.エッシャーと楽しむ算数・数学パズル」のp.138-143に紹介されている「トビウオの模様」を簡略化した形でProcessingで再現してみましたので、その描き方とともに解説したいと思います。

トビウオの模様

今回描いてみたトビウオの模様は以下のような図形になりました。

トビウオの模様

描き方

このトビウオの模様は壁紙群P2に分類されるものになります。トビウオの模様の基本図形は以下のような形状をしています。

トビウオの模様の基本図形

この基本図形を準備することができれば、後はP2群のルールに従って基本図形を並べていくことでトビウオの模様を描くことができます。

P2の基本図形を選ぶ

トビウオの模様の基本図形は、P2群の基本図形を変形して作成します。そのためにまずP2群の基本図形を選ぶ必要があります。以前紹介した記事「基本図形の形を考える」の「P2群の基本図形の形状」の節を参考にして、今回は三角形の形状を選びます。

P2群の基本図形として三角形を選ぶ

なお、この三角形の3つの頂点は、互いに隣り合った一般格子点上に乗っています。

P2群の基本図形の変形

P2群の基本図形を変形するために、隣り合う基本図形同士の辺のラベルと向きをみてみます。

P2群の基本図形に対する辺のラベルと向き

3つのすべての辺\(a,b,c\)についてそれぞれ両側のラベルが同じで向きが異なっていますので、中点に関して点対称な変形を行います。そうすると、隣り合う基本図形同士を重ねることなくP2群の対称性に従って敷き詰めることができます。

各辺の変形

各辺について、今回は以下の図のように変形しています。

各辺の変形

これらの変形を実施した結果、P2群の基本図形はトビウオの模様の基本図形に変形することができます。

P2群の基本図形をトビウオの模様の基本図形に変形

プログラムコード

P2群の基本図形を変形した基本図形をP2群の対称性を考慮して並べていくと、最初に示したような図形を得ることができます。

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP2(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("P2_flying_fish.jpg");
}

// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI * 3.5 / 12.0);
  base[1].mult(1.2);
}

// 一般格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2.0 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
    }
  }
}

// 三角形を変形する関数（基本図形）
PShape transformTriangle(){
  
  PVector[] v = new PVector[3]; // 三角形の頂点

  v[0] = base[0].copy();
  v[0].sub(base[1]);
  v[0].mult(-scalar / 2.0);
  v[1] = base[0].copy();
  v[1].add(base[1]);
  v[1].mult(scalar / 2.0);
  v[2] = base[0].copy();
  v[2].sub(base[1]);
  v[2].mult(scalar / 2.0);

  // 三角形を変形する
  PShape tri = createShape();
  tri.beginShape(); 
  PVector[] auxiliary_point = new PVector[6];
  // 辺aの変形
  tri.vertex(v[0].x, v[0].y);
  auxiliary_point[0] = getAuxiliaryPoint(v[0], v[1], 1.0/3.0, 1.0/4.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[0], v[1], 1.0/3.0, -1.0/5.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[0], v[1], 2.0/3.0, 1.0/5.0); 
  auxiliary_point[3] = getAuxiliaryPoint(v[0], v[1], 2.0/3.0, -1.0/4.0);
  for(int i=0; i<4; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[1].x, v[1].y); 
  // 辺bの変形
  auxiliary_point[0] = getAuxiliaryPoint(v[1], v[2], 1.0/4.0, 1.0/5.0);
  auxiliary_point[1] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, 1.0/10.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[1], v[2], 1.0/2.0, -1.0/10.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[1], v[2], 3.0/4.0, -1.0/5.0);
  for(int i=0; i<4; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[2].x, v[2].y); 
  // 辺cの変形
  auxiliary_point[0] = getAuxiliaryPoint(v[2], v[0], 1.0/4.0, 0.0); 
  auxiliary_point[1] = getAuxiliaryPoint(v[2], v[0], 3.0/8.0, 1.0/8.0);
  auxiliary_point[2] = getAuxiliaryPoint(v[2], v[0], 3.0/8.0, 1.0/4.0);
  auxiliary_point[3] = getAuxiliaryPoint(v[2], v[0], 5.0/8.0, -1.0/4.0);
  auxiliary_point[4] = getAuxiliaryPoint(v[2], v[0], 5.0/8.0, -1.0/8.0);
  auxiliary_point[5] = getAuxiliaryPoint(v[2], v[0], 3.0/4.0, 0.0);
  for(int i=0; i<6; i++){
    tri.vertex(auxiliary_point[i].x, auxiliary_point[i].y);
  }
  tri.vertex(v[0].x, v[0].y);
  
  tri.endShape();
  
  return tri;
}

// 辺を変形するために必要な補助点を算出する関数
PVector getAuxiliaryPoint(
  PVector start,
  PVector end, 
  float parallel_size,
  float vertical_size
){
  PVector dir_parallel = end.copy().sub(start.copy());
  PVector dir_vertical = new PVector(-dir_parallel.y, dir_parallel.x);
  PVector auxiliary_point = start.copy().add(dir_parallel.copy().mult(parallel_size)).add(dir_vertical.copy().mult(vertical_size));
  return auxiliary_point;
}

// タイルを生成する関数
void makeTileP2(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){    

    noStroke();
    if( i % 2 == 0 ){
      fill(255,255,255);
    } else {
      fill(0,0,0);
    }
    
    PShape tri = transformTriangle(); // 変形した三角形の生成
    tri.rotate(PI * i); // 180度回転
    tile.addChild(tri); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
}

コメントを残す