渦巻き図形（P3） - 数学アートの部屋

ここでは、P3のパターンで渦巻き図形による壁紙アートを作成しています。結果は以下のようになりました。

この壁紙アートにおける基本図形とタイルは以下のようなものです。タイルは基本図形を順に120°回転させたものを3つ組み合わせて作成しています。

以下、この図形を描画するためのプログラムソースコードを載せておきます（Processingで動きます）。

PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000,1000);
  scalar = width * 1.0 / col_num; // 描画ウィンドウと列の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP3(); // タイルを生成
  drawTiling(); // タイリングを描画
  
  save("P3_spiral.jpg");
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = PVector.fromAngle(0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
    }
  }
}

// 再帰的な正六角形を生成する関数（基本図形）
PShape makeRecurHexagon(){
  float gap = 0.2; // 再帰的な正六角形を作るパラメータ  
  
  PVector[] v = new PVector[6]; // 正六角形の頂点
//  v[3] = new PVector(0,0);
  for (int i=0; i<6; i++){
    v[i] = PVector.fromAngle(i * PI / 3 - 2.0 * PI / 3.0).mult(scalar / 3.0);
    v[i].add( base[1].copy().mult(scalar / 3.0) );
  }
  PShape hexagon = createShape();
  hexagon.beginShape(); // 6点ずつの頂点から正六角形の頂点を作る
  while( v[0].dist(v[1]) > 1){
    for (int i=0; i<6; i++){
      hexagon.vertex(v[i].x, v[i].y);
    }
    v = getVector(v, gap); // gapの分だけずらした正六角形の頂点を取得
  }
  hexagon.endShape();
  return hexagon;
}

PVector[] getVector(PVector[] v, float gap){
  PVector[] nextVec = new PVector[6];
  for (int i=0; i<6; i++){
    PVector dir = PVector.sub(v[(i+1)%6], v[i]);
    if(i == 0){
      dir.mult(gap/2.0); // 図形の形状を少しずつ変形していく
    } else {
      dir.mult(gap);
    }
    nextVec[i] = PVector.add(v[i], dir);
  }
  return nextVec;
}

// タイルを生成する関数
void makeTileP3(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<3; i++){
    PShape hexagon = makeRecurHexagon(); // 再帰的な正六角形の生成
    hexagon.rotate(2 * PI * i / 3); // 120度回転
    tile.addChild(hexagon); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
  background(255);
  for (PVector[] vecArr: lattice){
    for (PVector vec : vecArr){
      tile.resetMatrix();
      tile.translate(vec.x, vec.y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
  // 格子点を描く
  for (PVector[] vecArr: lattice){
    for (PVector vec : vecArr){
      circle(vec.x, vec.y,10);
    }
  }
}