正三角形と正方形②

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 8; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  noLoop();
  
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeSquareVector(); // 正方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP4G(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 正方格子を張るベクトルを生成する関数
void makeSquareVector(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点

  v[3] = new PVector(0.0,0.0);
  v[1] = new PVector(1.0,0.0).mult(scalar);
  v[0] = PVector.fromAngle( radians(60.0) ).mult( scalar / 2.0);
  v[2] = PVector.fromAngle( -radians(45.0) ).mult( scalar / sqrt(2.0));
  
  base[1] = v[0].copy().sub(v[2].copy());
  base[0] = base[1].copy().rotate( -radians(90.0) );
}

// 正方格子を生成する関数
void makeLattice(){
  int row_num = ceil(height / base[1].y); // 行の数
  lattice = new PVector[col_num + 5][row_num + 5];
  for (int i = 0; i < col_num + 5; i++){
    for (int j = 0; j < row_num + 5; j++){
      PVector v = PVector.mult(base[0], i-2); 
      v.add(PVector.mult(base[1], j-2));
      lattice[i][j] = new PVector(v.x, v.y);
    }
  }
}

// 四角形を生成する関数（基本図形）
PShape makeRectangle(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点

  v[3] = new PVector(0.0,0.0);
  v[1] = new PVector(1.0,0.0).mult(scalar);
  v[0] = PVector.fromAngle( radians(60.0) ).mult( scalar / 2.0);
  v[2] = PVector.fromAngle( -radians(45.0) ).mult( scalar / sqrt(2.0));

  PVector dir = v[2].copy();
  for(int i=0; i<4; i++){
    v[i].sub(dir.copy());
  }

  PShape rect = createShape(GROUP);

  // 直角二等辺三角形を描く
  fill(128,128,0);
  noStroke();
  PShape tri1 = createShape();
  tri1.beginShape(); 
  tri1.vertex(v[1].x, v[1].y);
  tri1.vertex(v[2].x, v[2].y);
  tri1.vertex(v[3].x, v[3].y);
  tri1.endShape(CLOSE);
  rect.addChild(tri1);

  // 30,60,90の直角三角形を描く
  fill(64,64,64);
  noStroke();
  PShape tri2 = createShape();
  tri2.beginShape(); 
  tri2.vertex(v[0].x, v[0].y);
  tri2.vertex(v[1].x, v[1].y);
  tri2.vertex(v[3].x, v[3].y);
  tri2.endShape(CLOSE);
  rect.addChild(tri2);

  // 三角形の一部の輪郭を描く
  stroke(0,0,0);
  PShape tri2_line = createShape();
  tri2_line.beginShape(); 
  tri2_line.vertex(v[0].x, v[0].y);
  tri2_line.vertex(v[3].x, v[3].y);
  tri2_line.vertex(v[0].x, v[0].y);
  tri2_line.endShape(CLOSE);
  rect.addChild(tri2_line);

  return rect;
}

// タイルを生成する関数
void makeTileP4G(){
  float angle = PVector.angleBetween( base[0], new PVector(1.0,0.0) );
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int j=0; j<2; j++){
    for(int i=0; i<4; i++){
      PShape square = makeRectangle(); // 変形した四角形の生成
      square.scale(pow(-1,j),1); // 四角形の反転 
      square.rotate(i*radians(90) + 2.0 * angle * j); // 四角形の回転
      square.translate(j*( base[0].x + base[1].x ), j*( base[0].y + base[1].y )); // 四角形の位置を調整
      tile.addChild(square); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2==0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画 
      }
    }
  }
}