正三角形と正方形①

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 16; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){
  
  size(1000, 1000, P2D);
  noFill();
  noLoop();
  scalar = width * 1.0 / ( col_num / 2.0 ); // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRhombusVector(); // 菱形格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileCMM(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 菱形格子を張るベクトルを生成する関数
void makeRhombusVector(){
  base[0] = new PVector(0.5, 0.0);
  base[1] = new PVector(0.25, (2.0+sqrt(3.0))/4.0);
}

// 菱形格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num+1][row_num];
  PVector v;
  for (int i = 0; i < col_num+1; i++){
    for (int j = 0; j < row_num; j++){
      if( j%2 == 0 ){
        v = new PVector(base[0].x * i * scalar, 0.0 ); 
        v.add( new PVector(0.0, base[1].y * j * scalar));
      } else {
        v = new PVector(base[0].x * i * scalar + base[1].x * scalar, 0.0 ); 
        v.add( new PVector(0.0, base[1].y * j * scalar));
      }
      lattice[i][j] = v;
    }
  }
}

// 四角形を生成する関数（基本図形）
PShape makeRectangle(){
  
  PVector[] v = new PVector[4]; // 四角形の頂点

  v[0] = new PVector(0.0,0.0);
  v[1] = base[0].copy().mult(scalar);
  v[2] = PVector.fromAngle( -radians(60.0) ).mult( scalar / 2.0 );
  v[2].add( new PVector( base[1].x, - base[1].y).mult(scalar) );
  v[3] = PVector.fromAngle( radians(120.0) ).mult( scalar / 2.0 );
  v[3].add( new PVector( base[1].x, - base[1].y).mult(scalar) );

  PVector v_middle = new PVector( 1.0 ,-1.0).mult(scalar / 2.0);
  
  PShape trapezium = createShape(GROUP);

  // 正方形を描く
  fill(255,0,0);
  noStroke();
  PShape rect = createShape();
  rect.beginShape(); 
  rect.vertex(v[0].x, v[0].y);
  rect.vertex(v[1].x, v[1].y);
  rect.vertex(v_middle.x, v_middle.y);
  rect.vertex(v[3].x, v[3].y);
  rect.endShape(CLOSE);
  trapezium.addChild(rect);

  // 30,60,90二等辺三角形を描く
  fill(0,0,255);
  PShape tri = createShape();
  tri.beginShape(); 
  tri.vertex(v_middle.x, v_middle.y);
  tri.vertex(v[2].x, v[2].y);
  tri.vertex(v[3].x, v[3].y);
  tri.endShape(CLOSE);
  trapezium.addChild(tri);

  // 正方形の一部の輪郭を描く
  stroke(0,0,0);
  PShape rect_line = createShape();
  rect_line.beginShape(); 
  rect_line.vertex(v[0].x, v[0].y);
  rect_line.vertex(v[3].x, v[3].y);
  rect_line.vertex(v[0].x, v[0].y);
  rect_line.endShape(CLOSE);
  trapezium.addChild(rect_line);
  
    // 三角形の一部の輪郭を描く
  stroke(0,0,0);
  PShape tri_line = createShape();
  tri_line.beginShape(); 
  tri_line.vertex(v[2].x, v[2].y);
  tri_line.vertex(v[3].x, v[3].y);
  tri_line.vertex(v_middle.x, v_middle.y);
  tri_line.endShape();
  trapezium.addChild(tri_line);
  
  return trapezium;
}

// タイルを生成する関数
void makeTileCMM(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){
    for(int j=0; j<2; j++){
      PShape rectangle = makeRectangle(); // 四角形の生成
      rectangle.scale(pow(-1,j),pow(-1,i)); // 四角形の反転
      tile.addChild(rectangle); // グループに追加
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( (j%4 == 0 && i%2 == 0 ) || (j%4 == 2 && i%2 == 1 ) ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      } 
    }
  }
}