五角形によるタイリング（Type 3）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 3; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000,1000,P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと列の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP3(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = PVector.fromAngle(0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 3][row_num + 1];
  for (int i = 0; i < col_num + 3; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x % ((col_num+3)*scalar) - 2 * scalar, v.y); // x軸方向にscalarの2倍だけ左にシフト
    }
  }
}

// 五角形を生成する関数（基本図形）
PShape makePentagon(){
  
  PVector[] v = new PVector[5]; // 六角形の頂点
  float r1, r2;
  r1 = 2.0/5.0;
  r2 = 3.0/5.0;

  v[4] = new PVector(0.0,0.0);
  v[1] = new PVector(1.0/sqrt(3.0) * scalar, 0.0);
  v[1].rotate(radians(90.0));
  v[2] = new PVector(1.0/sqrt(3.0) * scalar, 0.0);
  v[2].rotate(radians(30.0));
  v[0] = v[1].copy().add( v[2].copy().sub(v[1].copy()).rotate(radians(-120.0)).mult(r1) );
  v[3] = v[2].copy().add( v[1].copy().sub(v[2].copy()).rotate(radians(120.0)).mult(r2) );

  // 五角形を描く
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  for(int i=0; i<5; i++){
    pentagon.vertex(v[i].x, v[i].y);
  }
  pentagon.endShape(CLOSE);
  
  return pentagon;
}

// タイルを生成する関数
void makeTileP3(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<3; i++){
    PShape pentagon = makePentagon(); // 五角形の生成
    pentagon.rotate(2 * PI * i / 3); // 120度回転
    tile.addChild(pentagon); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
}