ガンガゼピンク

void setup() {
  size(1000, 1000);
  translate(width/2, height/2); // 座標の原点を画像の中心位置に移動
  
  color col_out = color(235,110,159); // 背景グラデーションの一番外側の色
  color col_in = color(228,0,127);   // 背景グラデーションの一番内側の色
  grdCircle(0, 0, width*sqrt(2.0), col_out, col_in); // 背景のグラデーションを描く

  float th1 = radians(1.0); 
  float th2 = radians(5.0);
  float line_num = 24; // 中心から伸びていく図形の数
  for(int i=0; i<line_num; i++){
    rotate(radians(360.0/line_num)); // 15°ずつ回転させる
    drawVshape(width, th1, th2); // V字の形状を描画
  }
  
  save("hatpin_urehin_pink.jpg");  // jpg画像として保存
  
}

// 円形のグラデーション
void grdCircle(
  float x, // 円の中心位置のx座標
  float y, // 円の中心位置のy座標 
  float d, // 一番外側の円の直径
  color col_out, // 背景グラデーションの一番外側の色
  color col_in   // 背景グラデーションの一番内側の色
  ) {
  float c = 100;
  for (int i=0; i<c; i++) {
    color col = lerpColor(col_out, col_in, i/c); // 円の色
    float dd = lerp(d, 0.0, i/c); // 円の直径

    noStroke();
    fill(col);
    ellipse(x, y, dd, dd); // 円を描く
  }
}

// V字の形状を作る関数
void drawVshape(
  float x,   // V字形状を作成する際の基準となるサイズ
  float th1, // V字形状を作成する際の基準となるx軸正の方向とのなす角
  float th2  // V字形状を作成する際の基準となるx軸負の方向とのなす角
  ){
  int i = 0;
  float a = 1.0/2.0;
  float r1, r2, r3;
  float x1, y1, x2, y2, x3, x4, y4;

  while(i<100){
    r1 = x * sin(th1) / sin(th1+th2);
    x1 = x - r1 * cos(th2);
    y1 = r1 * sin(th2);
    r2 = r1 * tan(th2);
    x2 = x1 - a * r2 * sin(th2);
    y2 = y1 - a * r2 * cos(th2);
    x3 = x - a * r1 / cos(th2);
    r3 = ((x-x2) * sin(th2) - y2 * cos(th2)) / sin(2.0*th2);
    x4 = x - r3 * cos(th2);
    y4 = r3 * sin(th2);
  
    noStroke();
    if (i % 2 == 0){
      fill(0,0,0);
    } else {
      fill(255,255,255);
    }
    pushMatrix();
    beginShape();
    vertex(x4,y4);
    vertex(x1,y1);
    vertex(x2,y2);
    vertex(x3,0);
    vertex(x2, -y2);
    vertex(x1, -y1);
    vertex(x4, -y4);
    endShape(CLOSE);
    popMatrix();
    
    x = x3;
    i++;
  }
}