五角形によるタイリング（Type 14）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
float pentagon_size = 50.0; // 五角形の基準サイズ
float pentagon_angle = 2.0 * asin( (sqrt(57.0)-3.0)/8.0 ); // Type 6の五角形の標準角度（頂点Cの角度）
PVector[] base = new PVector[2]; // 格子を張るベクトル

void setup(){
  
  size(1000, 1000, P2D);
  noFill();

  makeTileP2(); // タイルを生成
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  drawTiling(); // タイリングを描画
}

// 五角形の頂点を取得する関数
PVector[] getPentagon(){
  
  float A, B, C, D, E;
  C = pentagon_angle;
//  println(C * 180.0/PI);
  float r1 = pentagon_size;
  
  A = radians(90.0);
  B = radians(180.0) - C/2.0;
  D = radians(90.0) + C/2.0;
  E = radians(180.0) - C;
  
  PVector[] v = new PVector[6];
  v[1] = PVector.fromAngle(B).mult(r1/2.0);
  v[2] = PVector.fromAngle(B-radians(180.0)).mult(r1/2.0);
  v[3] = v[2].copy().add( PVector.fromAngle(C/2.0-radians(180.0)).mult(2.0*r1) );
  v[4] = v[3].copy().add( PVector.fromAngle(radians(90.0) + C).mult(2.0*r1) );
  v[0] = new PVector( v[4].x, v[1].y );
  
  return v;
}

// 五角形を指定された軸に対して鏡映する関数
PVector[] getReflection(
  PVector[] v, // 鏡映する元の図形の頂点座標
  int index1,  // 鏡映軸の指定するための始点位置のindex
  int index2   // 鏡映軸の指定するための終点位置のindex
){
  PVector[] ref = new PVector[5];
 
  PVector axis = v[index1].copy().sub(v[index2].copy());
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index1].copy());
    float t = temp.dot(axis)/ axis.dot(axis);
    PVector p = v[index1].copy().add( axis.copy().mult(t) );
    ref[i] = p.copy().mult(2.0).sub(v[i].copy());
  }
  
  return ref;
  
}

// 五角形を指定された点の周りで回転する関数
PVector[] getRotation(
  PVector[] v, // 回転する元の図形の頂点座標
  int index,   // 回転軸の座標位置のindex
  float angle  // 回転角度
){
  PVector[] rot = new PVector[5];
 
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index].copy());
    PVector p = temp.copy().rotate(radians(angle));
    rot[i] = v[index].copy().add(p.copy());
  }
  
  return rot;
  
}

// 一般格子を張るベクトルを生成する関数
void makeGeneralVector(){
  PVector[][] vforbase = new PVector[3][5]; // 一般格子を張るベクトルを求めるための３つの五角形の座標
  vforbase[0] = getPentagon();
  vforbase[1] = getReflection(vforbase[0], 0, 1);
  vforbase[2] = getRotation(vforbase[1], 3, 90.0+(pentagon_angle/2.0) * 180.0/PI);
  
  base[0] = vforbase[0][3].copy().add( vforbase[0][4].copy().sub(vforbase[0][3].copy()).mult(3.0/4.0) ).mult(-2.0);
  base[1] = vforbase[2][0].copy().add( vforbase[2][1].copy().sub(vforbase[2][0].copy()).mult(1.0/2.0) ).mult(2.0) ;
}

// 一般格子を生成する関数
void makeLattice(){
  int col_num = ceil(width / abs(base[0].x)) + 2; // 列数
  int row_num = ceil(height / abs(base[1].y)) + 2; // 行の数
  lattice = new PVector[col_num][row_num];
  for (int i = 0; i < col_num; i++){
    for (int j = 0; j < row_num; j++){
      PVector v = PVector.mult(base[0], i-1); 
      v.add(PVector.mult(base[1], j-1));
      lattice[i][j] = v.copy();
    }
  }
}

// 3つの五角形から構成される基本図形を生成する関数
PShape makeFundamentalShape(){

  PVector[][] v = new PVector[3][5]; // 基本図形を構成する3つの五角形の座標
  // 3つの五角形のそれぞれの座標を取得
  v[0] = getPentagon();
  v[1] = getReflection(v[0], 0, 1);
  v[2] = getRotation(v[1], 3, 90.0+(pentagon_angle/2.0) * 180.0/PI);
 
  // 五角形を3つ描いて1つのグループにまとめる
  PShape pentagons = createShape(GROUP);
  for(int i=0; i<3; i++){
    PShape pentagon = createShape();
    pentagon.beginShape(); 
    for(int j=0; j<5; j++){
      pentagon.vertex(v[i][j].x, v[i][j].y);
    }
    pentagon.endShape(CLOSE);
    pentagons.addChild(pentagon);
  }
  
  return pentagons;
}

// タイルを生成する関数
void makeTileP2(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){    
    PShape pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
    pentagons.rotate(PI * i); // 180度回転
    tile.addChild(pentagons); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
}