五角形によるタイリング（Type 13）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
float pentagon_size = 50.0;
float pentagon_angle = 110.0; // Type 12の五角形の標準角度（頂点Cの角度）

void setup(){

  size(1000, 1000, P2D);
  noFill();
 
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePGG(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 五角形の頂点を取得する関数
PVector[] getPentagon(){

  float r1 = pentagon_size;
  float A = radians(90.0);
  float C = radians(pentagon_angle);
  float B = radians(180.0)-C/2.0;
  float D = radians(90.0)+C/2.0;
  float E =radians(360.0)-2.0 * D;
  
  float tanalpha = (cos(C) + sin(C / 2.0)) / (4.0 * sin(C / 2.0) * sin(C) + sin(C) - cos(C / 2.0));
  float alpha = atan(tanalpha);
  float tanbeta = cos(alpha) * cos(alpha - C) / (sin(alpha) * cos(alpha - C) + cos(C / 2.0));
  float beta = atan(tanbeta);
  float r2 = r1 / tanalpha;
  float r3 = r1 * 2.0 * sin(alpha + beta - C/2.0) / sin(alpha + beta + C/2.0);
  float r4 = 2.0 * r1;
  float r5 = 2.0 * r1 - r3;

  PVector[] v = new PVector[5];
  v[2] = PVector.fromAngle(-radians(180.0)+B).mult(r3/2.0);
  v[1] = PVector.fromAngle(B).mult(r3/2.0);
  v[0] = v[1].copy().add( PVector.fromAngle(radians(180.0)).mult(r2) );
  v[4] = v[0].copy().add( PVector.fromAngle(-radians(90.0)).mult(r1) );
  v[3] = v[4].copy().add( PVector.fromAngle(-E+radians(90.0)).mult(r5) );

  return v;
}

// 五角形を指定された軸に対して鏡映する関数
PVector[] getReflection(
  PVector[] v, // 鏡映する元の図形の頂点座標
  int index1,  // 鏡映軸の指定するための始点位置のindex
  int index2   // 鏡映軸の指定するための終点位置のindex
){
  PVector[] ref = new PVector[5];
 
  PVector axis = v[index1].copy().sub(v[index2].copy());
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index1].copy());
    float t = temp.dot(axis)/ axis.dot(axis);
    PVector p = v[index1].copy().add( axis.copy().mult(t) );
    ref[i] = p.copy().mult(2.0).sub(v[i].copy());
  }
  
  return ref;
  
}

// 五角形を指定された点の周りで回転する関数
PVector[] getRotation(
  PVector[] v, // 回転する元の図形の頂点座標
  int index,   // 回転軸の座標位置のindex
  float angle  // 回転角度
){
  PVector[] rot = new PVector[5];
 
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index].copy());
    PVector p = temp.copy().rotate(radians(angle));
    rot[i] = v[index].copy().add(p.copy());
  }
  
  return rot;
  
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  PVector[][] vforbase = new PVector[3][5]; // 長方格子を張るベクトルを求めるための３つの五角形の座標
  vforbase[0] = getPentagon();
  vforbase[1] = getReflection(vforbase[0], 0, 1);
  vforbase[2] = getRotation(vforbase[1], 3, -90.0-pentagon_angle/2.0);

  base[0] = new PVector( vforbase[0][3].copy().add( vforbase[0][4].copy().sub(vforbase[0][3].copy()).mult(1.0/2.0) ).mag(), 0.0);
  base[1] = new PVector(0.0, vforbase[2][3].copy().add( vforbase[2][4].copy().sub(vforbase[2][3].copy()).mult(1.0/2.0) ).mag() );
}

// 長方格子を生成する関数
void makeLattice(){
  int col_num = ceil(width / base[0].x); // 列数
  int row_num = ceil(height / base[1].y); // 行の数
  lattice = new PVector[col_num+1][row_num+1];
  for (int i = 0; i < col_num+1; i++){
    for (int j = 0; j < row_num+1; j++){
      PVector v = PVector.mult(base[0], i); 
      v.add(PVector.mult(base[1], j));
      lattice[i][j] = v.copy();
    }
  }
}

// 2つの五角形から構成される基本図形を生成する関数
PShape makeFundamentalShape(){
  
  PVector[][] v = new PVector[2][5]; // 基本図形を構成する2つの五角形の座標
  // 2つの五角形のそれぞれの座標を取得
  v[0] = getPentagon();
  v[1] = getReflection(v[0], 0, 1);

  PVector lat = v[0][3].copy().add( v[0][4].copy().sub(v[0][3].copy()).mult(1.0/2.0) );
  float angle = PVector.angleBetween(lat, new PVector(1.0, 0.0));
  for(int i=0; i<5; i++){
    v[0][i].rotate(angle);
    v[1][i].rotate(angle);
  }
  
  // 五角形を2つ描いて1つのグループにまとめる
  PShape pentagons = createShape(GROUP);
  for(int i=0; i<2; i++){
    PShape pentagon = createShape();
    pentagon.beginShape(); 
    for(int j=0; j<5; j++){
      pentagon.vertex(v[i][j].x, v[i][j].y);
    }
    pentagon.endShape(CLOSE);
    pentagons.addChild(pentagon);
  }
  
  return pentagons;
}

// タイルを生成する関数
void makeTilePGG(){
  tile = createShape(GROUP); // PShapeのグループを作る

  PShape pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  tile.addChild(pentagons); // グループに追加
      
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.scale(pow(-1,1),pow(-1,1)); // 基本図形の反転
  tile.addChild(pentagons); // グループに追加
            
  float angle = radians(90.0); 
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.rotate(angle);
  pentagons.translate(-base[0].x-base[1].x, -base[0].y-base[1].y); // 基本図形の位置を調整
  tile.addChild(pentagons); // グループに追加
      
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.rotate(-angle);
  pentagons.translate(base[0].x + base[1].x, base[0].y + base[1].y); // 基本図形の位置を調整
  tile.addChild(pentagons); // グループに追加
  
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}