五角形によるタイリング（Type 7）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
PVector[][] v = new PVector[2][5]; // 基本図形を構成する2つの五角形の座標
float pentagon_size = 100.0;

void setup(){

  size(1000, 1000, P2D);
  noFill();
  
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePGG(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 五角形の頂点を取得する関数
PVector[] getPentagon(){

  float r1 = pentagon_size;
  float C = radians(80.0);
  float r2 = 2.0 * r1 * sin(C/2.0);
  float r3 = sqrt(r1*r1+r2*r2);
  float alpha = atan(r1/r2);
  float beta = atan( r1 * cos(C - alpha) / (r3 - r1 * sin(C - alpha)) );
  float D = alpha + beta + radians(90.0) - C/2.0;
  float A = radians(360.0) - 2.0 * D; 

  PVector[] v = new PVector[5];
  v[2] = PVector.fromAngle(-C/2.0).mult(r1/2.0);
  v[1] = PVector.fromAngle(radians(180.0)-C/2.0).mult(r1/2.0);
  v[0] = v[1].copy().add( PVector.fromAngle(radians(180.0)).mult(r1) );
  v[3] = v[2].copy().add( PVector.fromAngle(-radians(180.0)+C/2.0).mult(r1) );
  v[4] = v[0].copy().add( PVector.fromAngle(-A).mult(r1) );

  PVector lat = v[0].copy().add( v[4].copy().sub(v[0].copy()).mult(1.0/2.0) );
  float angle = PVector.angleBetween(lat, new PVector(-1.0, 0.0));
  for(int i=0; i<5; i++){
    v[i].rotate(-angle);
  }
  
  return v;
}

// 五角形を指定された軸に対して鏡映する関数
PVector[] getReflection(
  PVector[] v, // 鏡映する元の図形の頂点座標
  int index1,  // 鏡映軸の指定するための始点位置のindex
  int index2   // 鏡映軸の指定するための終点位置のindex
){
  PVector[] ref = new PVector[5];
 
  PVector axis = v[index1].copy().sub(v[index2].copy());
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index1].copy());
    float t = temp.dot(axis)/ axis.dot(axis);
    PVector p = v[index1].copy().add( axis.copy().mult(t) );
    ref[i] = p.copy().mult(2.0).sub(v[i].copy());
  }
  
  return ref;
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  v[0] = getPentagon();
  v[1] = getReflection(v[0], 3, 4);
  base[0] = new PVector(abs( v[0][0].copy().add( v[0][4].copy().sub(v[0][0].copy()).mult(1.0/2.0) ).x ), 0.0);
  base[1] = new PVector(0.0, abs( v[0][0].copy().sub( v[1][2].copy() ).y ) );
}

// 長方格子を生成する関数
void makeLattice(){
  int col_num = ceil(width / abs(base[0].x)); // 列数
  int row_num = ceil(height / abs(base[1].y)); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i); 
      v.add(PVector.mult(base[1], j));
      lattice[i][j] = new PVector(v.x, v.y);
    }
  }
}

// 2つの五角形から構成される基本図形を生成する関数
PShape makeFundamentalShape(){
  // 2つの五角形のそれぞれの座標を取得
  v[0] = getPentagon();
  v[1] = getReflection(v[0], 3, 4);

  // 五角形を2つ描いて1つのグループにまとめる
  PShape pentagons = createShape(GROUP);
  for(int i=0; i<2; i++){
    PShape pentagon = createShape();
    pentagon.beginShape(); 
    for(int j=0; j<5; j++){
      pentagon.vertex(v[i][j].x, v[i][j].y);
    }
    pentagon.endShape(CLOSE);
    pentagons.addChild(pentagon);
  }
  
  return pentagons;
}

// タイルを生成する関数
void makeTilePGG(){
  tile = createShape(GROUP); // PShapeのグループを作る

  PShape pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  tile.addChild(pentagons); // グループに追加
      
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.scale(pow(-1,1),pow(-1,1)); // 図形の反転
  tile.addChild(pentagons); // グループに追加
      
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.scale(pow(-1,1),pow(-1,0)); // 図形の反転
  pentagons.translate(-base[0].x, base[1].y); // 図形の位置を調整
  tile.addChild(pentagons); // グループに追加
      
  pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
  pentagons.scale(pow(-1,0),pow(-1,1)); // 図形の反転
  pentagons.translate(base[0].x, -base[1].y); // 図形の位置を調整
  tile.addChild(pentagons); // グループに追加

}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}