五角形によるタイリング（Type 6）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
float pentagon_size = 200.0; // 五角形の基準サイズ
float pentagon_angle = 40.0; // Type 6の五角形の標準角度（頂点Cの角度）
PVector[][] v = new PVector[2][5]; // 基本図形を構成する2つの五角形の座標
PVector[] base = new PVector[2]; // 格子を張るベクトル

void setup(){
  
  size(1000, 1000, P2D);
  noFill();

  makeTileP2(); // タイルを生成
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  drawTiling(); // タイリングを描画
}

// 五角形の頂点を取得する関数
PVector[] getPentagon(){
  
  float A, B, C, D, E;
  C = radians(pentagon_angle);
  
  float alpha = atan( 1.0 / 2.0 / sin(C) );
  float r1 = pentagon_size;
  float r2 = 2.0 * r1 * sin(C / 2.0) * sin(alpha);
  
  A = 2.0 * C;
  B = (radians(90.0) - A / 2.0) + alpha + (radians(90.0) - C / 2.0);
  D = (radians(90.0) - C / 2.0) + (radians(90.0) - alpha);
  E = radians(90.0) + (radians(90.0) - A / 2.0);
  
  PVector[] v = new PVector[6];
  v[0] = PVector.fromAngle(-B).mult(r2/2.0);
  v[1] = v[0].copy().rotate(radians(180.0));
  v[2] = v[1].copy().add( PVector.fromAngle(radians(0.0)).mult(r1));
  v[3] = v[2].copy().add( PVector.fromAngle(-(radians(180.0) - C)).mult(r1) );
  v[4] = v[0].copy().add(v[1].copy().sub(v[0].copy()).rotate(-A));
  
  return v;
}

// 五角形を指定された点の周りで回転する関数
PVector[] getRotation(
  PVector[] v, // 回転する元の図形の頂点座標
  int index,   // 回転軸の座標位置のindex
  float angle  // 回転角度
){
  PVector[] rot = new PVector[5];
 
  for(int i=0; i<5; i++){
    PVector temp = v[i].copy().sub(v[index].copy());
    PVector p = temp.copy().rotate(radians(angle));
    rot[i] = v[index].copy().add(p.copy());
  }
  
  return rot; 
}

// 2つの五角形から構成される基本図形を生成する関数
PShape makeFundamentalShape(){
  // 2つの五角形のそれぞれの座標を取得
  v[0] = getPentagon();
  v[1] = getRotation(v[0], 2, -pentagon_angle);

  // 五角形を2つ描いて1つのグループにまとめる
  PShape pentagons = createShape(GROUP);
  for(int i=0; i<2; i++){
    PShape pentagon = createShape();
    pentagon.beginShape(); 
    for(int j=0; j<5; j++){
      pentagon.vertex(v[i][j].x, v[i][j].y);
    }
    pentagon.endShape(CLOSE);
    pentagons.addChild(pentagon);
  }
  
  return pentagons;
}

// タイルを生成する関数
void makeTileP2(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){    
    PShape pentagons = makeFundamentalShape(); // 2つの五角形で構成される図形の生成
    pentagons.rotate(PI * i); // 180度回転
    tile.addChild(pentagons); // グループに追加
  }
}

// 一般格子を張るベクトルを生成する関数
// 基本図形のサイズから算出する
void makeGeneralVector(){
  base[0] = v[0][2].copy().add( v[0][3].copy().sub(v[0][2].copy()).mult(0.5) ).mult(2.0);
  base[1] = v[1][0].copy().add( v[1][4].copy().sub(v[1][0].copy()).mult(0.5) ).mult(2.0);
}

// 一般格子を生成する関数
void makeLattice(){
  int col_num = ceil(width / abs(base[0].x)) + 1; // 列数
  int row_num = ceil(height / abs(base[1].y)) + 2; // 行の数
  lattice = new PVector[col_num][row_num];
  for (int i = 0; i < col_num; i++){
    for (int j = 0; j < row_num; j++){
      PVector v = PVector.mult(base[0], i); 
      v.add(PVector.mult(base[1], j));
      lattice[i][j] = v.copy();
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
}