五角形によるタイリング（Type 5）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 4; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeTriangleVector(); // 三角格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTileP6(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 三角格子を張るベクトルを生成する関数
void makeTriangleVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 3);
}

// 三角格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].x); // 行の数
  lattice = new PVector[col_num + 5][row_num + 1];
  for (int i = 0; i < col_num + 5; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = new PVector(base[0].x * scalar * i - (j%2) * scalar /2.0, base[1].y * scalar * j); 
      lattice[i][j] = v;        
    }
  }
}

// 五角形を生成する関数（基本図形）
PShape makePentagon(){
  
  PVector[] v = new PVector[5]; // 五角形の頂点
  float r1, r2;
  r1 = 1.0/6.0 * scalar;
  r2 = 1.0/12.0 * scalar;

  v[0] = new PVector(-r2, -r1);
  v[0].sub(base[0].copy().mult(scalar));
  v[1] = new PVector(r2, r1);
  v[1].sub(base[0].copy().mult(scalar));
  v[2] = new PVector(0.0, 0.0);
  v[3] = v[1].copy().rotate(radians(60));
  v[4] = new PVector(0.0, -2.0 / 3.0 * base[1].y * scalar);
  v[4].sub(base[0].copy().mult(scalar));
  
  // 五角形を描く
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  for(int i=0; i<5; i++){
    pentagon.vertex(v[i].x, v[i].y);
  }
  pentagon.endShape(CLOSE);
  
  return pentagon;
}

// タイルを生成する関数
void makeTileP6(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for (int i=0; i<6; i++){
    PShape pentagon = makePentagon(); // 五角形の生成
    pentagon.rotate(PI * i / 3); // 60度回転
    tile.addChild(pentagon); // グループに追加
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( (i%2 == 0 && j%4 == 0) || (i%2 == 1 && j%4 == 2) ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}