五角形によるタイリング（Type 2）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
PVector[] base = new PVector[2]; // 格子を張るベクトル
int col_num = 6; // 描画するタイルの列の数
float scalar; // タイルの辺の長さ

void setup(){

  size(1000, 1000, P2D);
  noFill();
 
  scalar = width * 1.0 / col_num; // 描画ウィンドウと行の数からタイルの大きさを決定
  makeRectVector(); // 長方格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  makeTilePGG(); // タイルを生成
  drawTiling(); // タイリングを描画
}

// 長方格子を張るベクトルを生成する関数
void makeRectVector(){
  base[0] = new PVector(1.0, 0.0);
  base[1] = PVector.fromAngle(PI / 2.0);
  base[0].mult(1.5);
}

// 長方格子を生成する関数
void makeLattice(){
  int row_num = ceil(col_num / base[1].y); // 行の数
  lattice = new PVector[col_num + 1][row_num + 1];
  for (int i = 0; i < col_num + 1; i++){
    for (int j = 0; j < row_num + 1; j++){
      PVector v = PVector.mult(base[0], i * scalar); 
      v.add(PVector.mult(base[1], j * scalar));
      lattice[i][j] = new PVector(v.x , v.y);
    }
  }
}

// 五角形を生成する関数（基本図形）
PShape makePentagon(){
  
  PVector[] v = new PVector[5]; // 五角形の頂点
  float r1, r2, r3, r4;
  r1 = 1.0/6.0 * scalar * base[1].y;
  r2 = 5.0/6.0 * scalar * base[1].y;
  r3 = 1.0/6.0 * scalar * base[1].y;  
  r4 = 1.0/10.0 * scalar * base[0].x;

  v[0] = new PVector(-r4, r3);
  v[1] = new PVector(r4, -r3);
  v[2] = new PVector(-r4 * r1 / (r1 + r2), -scalar * base[1].y - r1);
  v[3] = new PVector(-scalar * base[0].x + r4, -scalar * base[1].y + r3);
  v[4] = new PVector(-scalar * base[0].x + r4 * r1 / (r1 + r2), -r1);
 
  // 五角形を描く
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  for(int i=0; i<5; i++){
    pentagon.vertex(v[i].x, v[i].y);
  }
  pentagon.endShape(CLOSE);
  
  return pentagon;
}

// タイルを生成する関数
void makeTilePGG(){
  tile = createShape(GROUP); // PShapeのグループを作る

  PShape pentagon = makePentagon(); // 五角形の生成
  tile.addChild(pentagon); // グループに追加
      
  pentagon = makePentagon(); // 五角形の生成
  pentagon.scale(pow(-1,1),pow(-1,1)); // 反転
  tile.addChild(pentagon); // グループに追加
      
  pentagon = makePentagon(); // 五角形の生成
  pentagon.scale(pow(-1,1),pow(-1,0)); // 反転
  pentagon.translate(-scalar*base[0].x, scalar*base[1].y); // 五角形の位置を調整
  tile.addChild(pentagon); // グループに追加
     
  pentagon = makePentagon(); // 五角形の生成
  pentagon.scale(pow(-1,0),pow(-1,1)); // 反転
  pentagon.translate(scalar*base[0].x, -scalar*base[1].y); // 五角形の位置を調整
  tile.addChild(pentagon); // グループに追加
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      if( i%2 == 0 && j%2 == 0 ){
        tile.resetMatrix();
        tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
        shape(tile); // タイルを描画
      }
    }
  }
}