五角形によるタイリング（Type 1）

PVector[][] lattice; // 格子点ベクトル
PShape tile; // タイル
float pentagon_size = 100.0; // 五角形の基準サイズ
PVector[] v = new PVector[5]; // 基本図形を構成する五角形の座標
PVector[] base = new PVector[2]; // 格子を張るベクトル

void setup(){
  
  size(1000, 1000, P2D);
  noFill();

  makeTileP2(); // タイルを生成
  makeGeneralVector(); // 一般格子を張るベクトルの生成
  makeLattice(); // 格子点ベクトルを生成
  drawTiling(); // タイリングを描画
}

// 五角形の頂点を取得する関数
PVector[] getPentagon(){
  
  PVector[] v = new PVector[5];
  v[4] = PVector.fromAngle(radians(75.0)).mult(pentagon_size/2.0);
  v[3] = PVector.fromAngle(radians(-105.0)).mult(pentagon_size/2.0);
  v[0] = v[4].copy().add( new PVector(pentagon_size, 0.0) );
  v[2] = v[3].copy().add( new PVector(1.2 * pentagon_size, 0.0) );
  v[1] = v[0].copy().add( PVector.fromAngle(radians(-50.0)).mult(pentagon_size * 2.0/5.0));
  
  return v;
}

// 基本図形を生成する関数
PShape makeFundamentalShape(){
  // 五角形の座標を取得
  v = getPentagon();

  // 五角形を描く
  PShape pentagon = createShape();
  pentagon.beginShape(); 
  for(int j=0; j<5; j++){
    pentagon.vertex(v[j].x, v[j].y);
  }
  pentagon.endShape(CLOSE);
  
  return pentagon;
}

// タイルを生成する関数
void makeTileP2(){
  tile = createShape(GROUP); // PShapeのグループを作る
  for(int i=0; i<2; i++){    
    PShape pentagon = makeFundamentalShape(); // 6つの五角形で構成される図形の生成
    pentagon.rotate(PI * i); // 180度回転
    tile.addChild(pentagon); // グループに追加
  }
}

// 一般格子を張るベクトルを生成する関数
// 基本図形のサイズから算出する
void makeGeneralVector(){
  base[0] = v[1].copy().add( v[2].copy().sub(v[1].copy()).mult(0.5) ).mult(2.0);
  base[1] = v[0].copy().add( v[1].copy().sub(v[0].copy()).mult(0.5) );
  base[1] = base[1].sub( v[1].copy().add( v[2].copy().sub(v[1].copy()).mult(0.5) ) );
  base[1] = base[1].mult(2.0);
}

// 一般格子を生成する関数
void makeLattice(){
  int col_num = ceil(width / base[0].x) + 1; // 列数
  int row_num = ceil(height / base[1].y) + 1; // 行の数
  lattice = new PVector[col_num][row_num];
  for (int i = 0; i < col_num; i++){
    for (int j = 0; j < row_num; j++){
      PVector v = PVector.mult(base[0], i); 
      v.add(PVector.mult(base[1], j));
      lattice[i][j] = v.copy();
    }
  }
}

// 格子形状に合わせたタイリングを描画する関数
void drawTiling(){
//  background(255);
  for (int i=0; i<lattice.length; i++){
    for (int j=0; j<lattice[0].length; j++){
      tile.resetMatrix();
      tile.translate(lattice[i][j].x, lattice[i][j].y); // タイルの位置を指定
      shape(tile); // タイルを描画
    }
  }
}